Dokumentation/Calc Funktionen/SCHALTER
TDF LibreOffice Document Liberation Project Community Blogs Weblate Nextcloud Redmine Ask LibreOffice Spende
Funktionsname:
SCHALTER
Kategorie:
Logisch
Zusammenfassung:
Vergleicht einen mitgegebenen Ausdruck gegen ein Set aus erwarteten Werten und gibt das Ergebnis, das zum ersten übereinstimmenden Wert gehört, zurück. Falls es keinen Treffer gibt, wird ein Standardwert zurückgegeben, falls einer angegeben ist.
Syntax:
SCHALTER(Ausdruck; Wert 1; Ergebnis 1 [; Wert 2; Ergebnis 2][; ... [Wert 127; Ergebnis 127][; Standardergebnis]])
Rückgabewerte:
Gibt einen Wert zurück, dessen Typ von der Natur des gewählten Ergebnisses abhängt.
Argumente:
Ausdruck ist ein Ausdruck oder eine Refenz auf eine Zelle, die den Ausdruck enthält, der mit den Wert n Argumenten abgeglichen wird.
Wert 1, Wert 2, ..., Wert 127 sind Ausdrücke oder Referenzen auf Zellen, die die Ausdrücke enthalten, gegen die der Ausdruck abgeglichen wird. Jeder Wert n muss ein entsprechendes Ergebnis n haben.
Ergebnis 1, Ergebnis 2, ..., Ergebnis 127 sind Ausdrücke oder Referenzen auf Zellen, die die Ausdrücke enthalten die die zurückzugebenden Ergebnisse liefern, wenn ein entsprechender Wert n mit dem Ausdruck übereinstimmt.
Standardergebnis ist ein Ausdruck oder eine Referenz auf eine Zelle, die den Ausdruck enthält die das zurückzugebende Ergebnis liefert, wenn kein entsprechender Wert n mit dem Ausdruck übereinstimmt.
- Wenn kein Standardergebnis angegeben ist, können 127 Wert / Ergebnis Paare mitgeliefert werden. Falls ein Standardergebnis am Ende der Liste steht, können nur 126 Wert / Ergebnis Paare mitgegeben werden.
- Falls kein Wert n zum Ausdruck passt und kein Standardergebnis angegeben ist, meldet SCHALTER einen #NV Fehler.
Zusätzliche Informationen:
Spezifische Eigenheiten der Funktion SCHALTER
- Die Funktion SCHALTER kann oft als leichter lesbare und effizientere Alternative zu verschachtelten WENN Funktionen dienen.
- SCHALTER gibt es seit LibreOffice 5.2. Aus Kompatibilitätsgründen ist daher Vorsicht geboten.
- Diese Funktion ist nicht Teil des Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. Der Namensraum ist
COM.MICROSOFT.SWITCH. Aus Kompatibilitätsgründen ist daher Vorsicht geboten.
Allgemeine Informationen über die logischen Funktionen in Calc
 |
Anmerkung:
|
Calc verwendet die Zahlen 0 (FALSCH) und 1 (WAHR) um logische Werte auszudrücken. Geben Sie zum Beispiel 1 in eine Zelle im allgemeinen Zahlenformat ein. Gehen Sie dann auf ▸ in der Menüleiste, wählen Sie Wahrheitswert im Feld Kategorie des Tabs Zahlen und klicken auf . Beachten Sie, das die Zahl 1 jetzt als WAHR angezeigt wird. Um die Anzeige zurückzustellen, wiederholen Sie den Vorgang, wählen Sie aber Dezimalzahl anstatt Wahrheitswert.
Um einen logischen Wert in eine Zelle einzugeben, tippen Sie einfach WAHR oder FALSCH (case-insensitive) in die Zelle ein. Calc erkennt den logischen Wert, zeigt ihn in Großbuchstaben an und ändert die Formatierung der Zelle auf Wahrheitswert.
Calc Funktionen, die einen Wahrheitswert erzeugen, geben ihn als Zahl, entweder 0 oder 1, zurück. Im Fall einer Formel, die eine solche logische Funktion aufruft und in einer Zelle mit einer Formatierung zur Dezimalzahl wird die Formatierung der Zelle auf einen Wahrheitswert geändert. Dabei wird der Rückgabewert als FALSCH oder WAHR angezeigt. Zum Beispiel gibt =WAHR() den Wert 1 zurück. Dieser wird als WAHR angezeigt. Falls Sie die Formatierung der Zelle auf Dezimalzahl ändern, wird die Zahl 1 angezeigt.
Calc Funktionen, die auf einen Wahrheitswert testen, tun dies immer, in dem Sie den Ausdruck auf den Wert 0 testen. Der Wert 0 wird als FALSCH angesehen. Jeder andere Wert wird als WAHR angesehen. Zum Beispiel gibt =NICHT(0) WAHR zurück, während =NICHT(57.89) FALSCH zurückgibt.
Im Gegensatz zu Calc hat Microsoft EXCEL einen seperaten Typ für logische Werte - sie sind keine Zahlen sondern werden manchmal in Zahlen umgewandelt. Also Vorsicht bei Kompatibilitätsbedarf.
Beispiele:
Basis Beispiele
Angenommen, A1 enthält ein beliebiges Datum. Die folgende Formel extrahiert den Monat aus dem Datum als eine Ganzzahl und konvertiert die Zahl in eine Zeichenkette mit der dreibuchstabigen Abkürzung des Monats.
=SCHALTER(MONAT(A1); 1; "Jan" ; 2; "Feb" ; 3; "Mär" ; 4; "Apr" ; 5; "Mai" ; 6; "Jun" ; 7; "Jul" ; 8; "Aug" ; 9; "Sep" ; 10; "Okt" ; 11; "Nov" ; 12; "Dez")
- Falls A1 den 02.02.1965 enthält, dann gibt die Funktion "Feb" zurück.
- Falls A1 445328 enthält, dann gibt Die Formel "Nov" zurück. 44528 Ist der Zeitstempel des 28.11.2021, vorausgesetzt das standardmäßige Datum 0 ist der 30.12.1899
umfassender Gebrauch von Referenzen auf Zellen
Angenommen, eine lokale Pizzeria verkauft kleine, mittlere, große und extra große Pizzen. Der Preis dieser Pizzen beträgt $ 9,49, $ 10,99, $ 12,99 und $ 14,98.
Vier Kunden bestellen Pizzen - Aidan (4 x extra groß), Jimmy (3 x groß), Lara (2 x medium) und Natalie (1 x klein).
Wie viel muss jeder Kunde zahlen?
Arrangieren wir die bekannten Daten in einer Tabelle wie folgt. Die Funktion SCHALTER kann in den Zellen D9:D12 genutzt werden um zu errechnen, welche Summe jeder Kunde schuldig ist.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Speisekarte | |||
| 2 | Größe | Preis | ||
| 3 | S | $9,49 | ||
| 4 | M | $10,99 | ||
| 5 | L | $12,99 | ||
| 6 | XL | $14,98 | ||
| 7 | ||||
| 8 | Kunde | gewünschte Größe | Menge | Gesamtpreis |
| 9 | Aidan | XL | 4 | $59,92 |
| 10 | Jimmy | L | 3 | $38,97 |
| 11 | Lara | M | 2 | $21,98 |
| 12 | Natalie | S | 1 | $9,49 |
- Zelle D9 enthält die Formel
=C9*SCHALTER(B9; $A$3; $B$3 ; $A$4; $B$4 ; $A$5; $B$5 ; $A$6; $B$6).
- Zelle D10 enthält die Formel
=C10*SCHALTER(B10; $A$3; $B$3 ; $A$4; $B$4 ; $A$5; $B$5 ; $A$6; $B$6).
- Zellen D11 und D12 enthalten die Formel nach dem gleichen Muster.
Komplexere Bedingungen
Lassen wir uns die Daten in der folgenden Tabelle durch den Kopf gehen.
Die Daten in den Zellen A2:C7 definieren die Noten für eine spezielle Prüfung in Angaben zur oberen und unteren Punktezahl für jede Note (in Prozent).
Sieben Schüler (Zellen A10:A16) absolvierten die Prüfung und und ihre Punkte erscheinen in den Zellen B10:B16. Unglücklicherweise sind zwei offensichtliche Fehler in den Prüfungsbewertungen passiert!
Die Funktion SCHALTER kann genutzt werden, um in den Zellen C10:C16 die richtigen Noten für jede Person anzugeben.
| A | B | C | |
|---|---|---|---|
| 1 | Noten | ||
| 2 | untere Punktegrenze | obere Punktegrenze | Note |
| 3 | 0 | 40 | 5 |
| 4 | 40 | 50 | 4 |
| 5 | 50 | 60 | 3 |
| 6 | 60 | 70 | 2 |
| 7 | 70 | 100 | 1 |
| 8 | |||
| 9 | Schüler | Punkte | Note |
| 10 | Angelina | -10 | Ungültige Bewertung |
| 11 | Annie | 35 | 5 |
| 12 | Carl | 45 | 4 |
| 13 | Hubert | 55 | 3 |
| 14 | Lula | 65 | 2 |
| 15 | May | 75 | 1 |
| 16 | Winston | 110 | Ungültige Bewertung |
- Die folgende Formel steht in Zelle C10:
=SCHALTER(WAHR();
UND(B10>=$A$3; B10<$B$3); $C$3;
UND(B10>=$A$4; B10<$B$4); $C$4;
UND(B10>=$A$5; B10<$B$5); $C$5;
UND(B10>=$A$6; B10<$B$6); $C$6;
UND(B10>=$A$7; B10<=$B$7); $C$7; "Ungültige Bewertung")
- Eine ähnliche Formel steht in den Zellen C11:C16, die Referenz auf Zelle B10 wir durch die Referenz auf Zellen B11, B12, B13, B14, B15 und B16 ersetzt.
Die Eingabefehler in der Bewertung für Angelina und Winston zeigen sich durch die Note "Ungültige Bewertung". Die wird durch die Angabe des Standardergebnisses mit dem Text "Ungültige Bewertung" erreicht.
Ähnliche LibreOffice Funktionen:
ODF Standard:
Nichts.
Betroffene (oder ähnliche) EXCEL-Funktionen:
SWITCH seit Version 2016.