Documentatie/Calc-functies/SCHAKELEN

This page is a translated version of the page Documentation/Calc Functions/SWITCH and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Deutsch
English
Nederlands

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

SCHAKELEN

Categorie:

Logisch

Samenvatting:

Vergelijkt een opgegeven expressie of uitdrukking met een set verwachte waarden en retourneert het resultaat dat overeenkomt met de eerste overeenkomende waarde. Als er geen overeenkomst is, wordt een standaardresultaat geretourneerd, indien opgegeven.

Syntaxis:

SCHAKELEN(Uitdrukking; Waarde 1; Resultaat 1 [; Waarde 2; Resultaat 2][; ... ; [Waarde 127; Resultaat 127][; Standaardresultaat]])

Retourneert:

Retourneert een waarde waarvan het type afhangt van de aard van het geselecteerde argument.

Argumenten:

Uitdrukking is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die evalueert tot een waarde die moet worden vergeleken met de Waarde n-argumenten.

Waarde 1, Waarde 2, ..., Waarde 127 zijn uitdrukkingen of verwijzingen naar cellen die uitdrukkingen bevatten, die evalueren naar waarden die moeten worden vergeleken met Uitdrukking. Elk Waarde n-argument moet een bijbehorend Resultaat n-argument hebben.

Resultaat 1, Resultaat 2, ..., Resultaat 127 zijn uitdrukkingen of verwijzingen naar cellen die uitdrukkingen bevatten, die de resultaten opleveren die moeten worden geretourneerd wanneer een corresponderend Waarde n argument overeenkomt met Uitdrukking.

Standaardresultaat is een uitdrukking of een verwijzing naar een cel die een uitdrukking bevat, die het resultaat geeft dat moet worden geretourneerd als er geen argument Waarde n overeenkomt met Uitdrukking.

Als u ervoor kiest om geen standaardresultaat op te geven, kunnen 127 waarde-/resultaatparen als parameters worden ingevoerd. Als u ervoor kiest om een standaardresultaat aan het einde van de lijst met parameters op te nemen, kunnen er slechts 126 waarde-/resultaatparen worden ingevoerd.
Als geen Waarde n-argument overeenkomt met Expressie en er geen argument Standaardresultaat is opgegeven, retourneert SCHAKELEN de fout #N/B.

Aanvullende details:

Details specifiek voor de functie SCHAKELEN

De functie SCHAKELEN kan vaak worden gebruikt als een beter leesbaar en efficiënter alternatief voor geneste functies ALS.
SCHAKELEN is beschikbaar sinds LibreOffice 5.2. Wees daarom voorzichtig als u compatibiliteit nodig hebt.
Deze functie maakt geen deel uit van het Open Document Formaat voor Office Applicaties (OpenDocument) versie 1.3. Deel 4: Herberekende Formule (OpenFormula) Formaat standaard. De namespace is COM. MICROSOFT.SWITCH. Wees daarom voorzichtig als u compatibiliteit nodig hebt.

Algemene informatie over de logische functies van Calc

NB:
Voor het gemak wordt de informatie in deze subsectie herhaald op alle pagina's die de logische functies van Calc beschrijven.

Calc gebruikt de getallen 0 (ONWAAR) en 1 (WAAR) om logische waarden weer te geven. Voer bijvoorbeeld 1 in in een cel met de standaard algemene getalopmaak. Selecteer vervolgens Opmaak ▸ Cellen op de Menubalk om het dialoogvenster Cellen opmaken weer te geven, selecteer de optie Booleaanse waarde in het gedeelteCategorie van het tabblad Getallen en klik op de knop OK. Merk op dat het getal 1 nu wordt weergegeven als WAAR. Om terug te keren naar het weergeven van het getal 1, herhaalt u het proces maar selecteert u Getal in plaats van Booleaanse waarde.

Om een logische waarde in een cel in te voeren, typt u gewoon WAAR of ONWAAR (hoofdletterongevoelig) in de cel. Calc zal de logische waarde herkennen, deze in hoofdletters weergeven en de opmaak van de cel wijzigen in de opmaak die past bij Booleaanse waarden.

Calc-functies die een logisch resultaat produceren, geven een getal terug, of 0 of 1. In het geval van een formule die zo'n logische functie eenvoudig aanroept en zich in een cel bevindt die de standaard algemene getalopmaak heeft, wordt de cel overgeschakeld naar de opmaak van de Booleaanse waarde en de geretourneerde waarde wordt weergegeven als ONWAAR of WAAR. Bijvoorbeeld =WAAR() retourneert de waarde 1, die wordt weergegeven als WAAR; als u de opmaak vervolgens wijzigt in een numerieke opmaak, wordt het weergegeven als het getal 1.

Calc-functies die op een logisch resultaat testen, evalueren altijd de te testen uitdrukking en controleren of deze gelijk is aan 0. De waarde 0 wordt als ONWAAR beschouwd en elke andere waarde wordt als WAAR genomen. Bijvoorbeeld, =NIET(0) geeft WAAR terug en =NIET(57,89) geeft ONWAAR terug.

In tegenstelling tot Calc heeft Microsoft Excel een apart type voor logische waarden - het zijn geen getallen maar worden soms geconverteerd naar getallen. Wees daarom voorzichtig als u compatibiliteit nodig heeft.

Voorbeelden:

Basisvoorbeeld

Stel dat de cel A1 een willekeurige datum bevat. Vervolgens zal de volgende formule de maandwaarde van die datum extraheren als een geheel getal en het getal vervolgens converteren naar een tekenreeks die een afkorting van drie tekens van de maand geeft.

=SCHAKELEN(MAAND(A1); 1; "Jan"; 2; "Feb"; 3; "Mrt"; 4; "Apr"; 5; "Mei"; 6; "Jun"; 7; "Jul"; 8; "Aug"; 9; "Sep"; 10; "Okt"; 11; "Nov"; 12; "Dec")

Als A1 de datum 1965-02-02 bevat, retourneert de formule "Feb".
Als A1 het getal 44528 bevat, retourneert de formule "Nov". 44528 is het datum-tijd-seriële getal dat overeenkomt met 2021-11-28, ervan uitgaande dat de standaarddag 0 van 1899-12-30 wordt toegepast.

Gebruik van celverwijzingen

Stel dat een plaatselijke winkel kleine, middelgrote, grote en extra grote pizza's verkoopt. De prijzen van deze pizza's zijn respectievelijk $9,49, $10,99, $12,99, en $14,98.

Vier klanten kopen pizza's: Aidan (extra groot x 4), Jimmy (groot x 3), Lara (middelgroot x 2) en Natalie (klein x 1).

Hoeveel betaalt elke klant in totaal?

Rangschik de bekende gegevens in een werkblad, zoals in de volgende tabel. De functie SCHAKELEN kan worden gebruikt in cellen D9:D12 om het door elke persoon verschuldigde bedrag te berekenen.

	A	B	C	D
1	Menu
2	Grootte	Prijs
3	S	$9,49
4	M	$10,99
5	L	$12,99
6	XL	$14,98
7
8	Klant	Gewenste grootte	Aantal	Totale kosten
9	Aidan	XL	4	$59,92
10	Jimmy	L	3	$38,97
11	Lara	M	2	$21,98
12	Natalie	S	1	$9,49

Cel D9 bevat de formule
=C9*SCHAKELEN(B9; $A$3; $B$3 ; $A$4; $B$4 ; $A$5; $B$5 ; $A$6; $B$6).
Cel D10 bevat de formule
=C10*SCHAKELEN(B10; $A$3; $B$3 ; $A$4; $B$4 ; $A$5; $B$5 ; $A$6; $B$6).
Cellen D11 en D12 volgen hetzelfde patroon.

Complexere voorwaarden

Bekijk de gegevens in de volgende tabel.

De gegevens in cellen A2:C7 definiëren het referentiekader voor een bepaald examen, in termen van de lage en hoge examenscores voor elk kader (als percentages).

Zeven studenten (cellen A10:A16) hebben het examen afgelegd en hun scores verschijnen in cellen B10:B16. Helaas zijn er twee duidelijke fouten bij het invoeren van gegevens in de examenscores opgetreden!

De functie SCHAKELEN kan worden gebruikt in cellen C10:C16 om te bepalen in welke referentiekader de examenscore van elke persoon ligt.

	A	B	C
1	Referentiekaders
2	Lage score	Hoge score	Referentiekader
3	0	40	5
4	40	50	4
5	50	60	3
6	60	70	2
7	70	100	1
8
9	Student	Examenscore	Referentiekader
10	Angelina	-10	Ongeldige score
11	Annie	35	5
12	Carl	45	4
13	Hubert	55	3
14	Lula	65	2
15	May	75	1
16	Winston	110	Ongeldige score

De volgende formule wordt ingevoerd in cel C10:

=SCHAKELEN(WAAR(); 
 EN(B10>=$A$3; B10<$B$3); $C$3; 
 EN(B10>=$A$4; B10<$B$4); $C$4; 
 EN(B10>=$A$5; B10<$B$5); $C$5; 
 EN(B10>=$A$6; B10<$B$6); $C$6; 
 EN(B10>=$A$7; B10<=$B$7); $C$7; "Ongeldige score")

Een vergelijkbare formule wordt ingevoerd in cellen C11:C16, maar met verwijzingen naar B10 die zijn vervangen door verwijzingen naar respectievelijk B11, B12, B13, B14, B15 en B16.

Merk op dat de fouten bij het invoeren van gegevens in de examenscores voor Angelina en Winston zich manifesteren met een referentiekader van "Ongeldige score". Dit wordt bereikt door het argument Standaardresultaat in te stellen op de tekenreeks "Ongeldige score".