Documentazione/Funzioni di Calc/AMMORT.VAR

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/VDB and the translation is 100% complete.

    TDF LibreOffice Document Liberation Project Blog comunitari Weblate Nextcloud Redmine Ask LibreOffice Donazione

    Other languages:

    Nome funzione:

    AMMORT.VAR

    Categoria:

    Analisi finanziaria

    Riepilogo:

    Calcola l'ammortamento di un bene per un intervallo di tempo arbitrario, basandosi principalmente su un metodo a "saldo decrescente" a tasso variabile. AMMORT.VAR è l'acronimo di Saldo decrescente variabile. Questo metodo calcola l'ammortamento in base al valore contabile corrente del bene (anziché al costo originale) e questo diminuisce da un periodo all'altro. Ciò fa sì che l’ammortamento sia maggiore nei periodi precedenti e minore in quelli successivi

    A differenza della funzione AMMORT, che utilizza lo stesso metodo del saldo decrescente a tasso variabile, AMMORT.VAR offre ulteriore flessibilità come segue:

    • AMMORT.VAR consente all'utente di definire il tempo di ammortamento come periodo iniziale e finale all'interno della vita utile del cespite. I periodi di inizio e fine possono avere parti frazionarie.
    • AMMORT.VAR fornisce un'opzione che consente di ammortizzare inizialmente il bene utilizzando il metodo del "saldo decrescente" a tasso variabile, passando all'ammortamento "a quote costanti" quando viene calcolato per essere maggiore dell'ammortamento del "saldo decrescente".

    Sintassi:

    AMMORT.VAR(Costo; Valore residuo; Vita utile; Inizio; Fine[; Fattore[; NessunCambio]])

    Restituisce:

    Restituisce un numero reale non negativo, ovvero l'ammortamento del bene per un intervallo di tempo specificato. Il numero restituito è nella stessa unità di valuta dei valori di costo e recupero specificati e per impostazione predefinita è formattato in un formato di valuta dipendente dalle impostazioni locali.

    Argomenti:

    Costo è un numero reale non negativo o un riferimento a una cella contenente quel numero, che rappresenta il costo o il valore del bene prima dell'ammortamento.

    Valore residuo è un numero reale non negativo, oppure un riferimento ad una cella contenente quel numero, che rappresenta il valore residuo del bene al termine della sua vita ammortizzata. Valore residuo deve essere espresso nella stessa unità di valuta di Costo.

    Vita utile è un numero reale non negativo, o un riferimento a una cella contenente quel numero, che definisce il numero di periodi durante i quali il bene viene ammortizzato.

    Inizio è un numero reale non negativo, o un riferimento a una cella contenente quel numero, che specifica il punto della vita della risorsa in cui dovrebbe iniziare AMMORT.VAR calcolo dell'ammortamento. Inizio deve essere nelle stesse unità di tempo di Vita utile.

    Fine è un numero reale non negativo, o un riferimento a una cella contenente quel numero, che specifica il punto della vita della risorsa in cui AMMORT.VAR dovrebbe terminare calcolo dell'ammortamento. Fine deve essere espresso nelle stesse unità di tempo di Vita utile e Inizio.

    Fattore è un numero reale positivo, o un riferimento a una cella contenente quel numero, che specifica il fattore di ammortamento da utilizzare per il metodo del saldo decrescente a tasso variabile. Se non viene specificato un valore, il valore predefinito è 2. Se Fattore = 2, allora AMMORT.VAR utilizza il metodo del doppio saldo decrescente. Se Fattore = 3, allora AMMORT.VAR utilizza il metodo del triplo saldo decrescente.

    NessunCambio è un valore logico, o un riferimento a una cella contenente un valore logico, che determina se AMMORT.VAR è in grado di passare alla linea retta ammortamento quando è maggiore dell'ammortamento a “saldo decrescente”. Se NessunCambio viene omesso, oppure FALSO, o impostato su 0 (zero), allora AMMORT.VAR automaticamente passa all'ammortamento a “linee costanti” quando questo è maggiore dell'ammortamento a “saldo decrescente”. Se NessunCambio è VERO o è impostato su un valore numerico diverso da zero, allora AMMORT.VAR non passa mai a ammortamento “a linee costanti”.

    • Se un argomento non è numerico, allora AMMORT.VAR segnala un errore #VALORE!.
    • La funzione segnala un errore di argomento non valido (Err:502) in una qualsiasi delle seguenti circostanze:
      • Costo < 0.
      • Valore residuo > Costo.
      • Fattore ≤ 0.
      • Inizio < 0.
      • Fine > Vita utile.
      • Fine < Inizio.

    Dettagli aggiuntivi:

    • Per calcolare l'ammortamento utilizzando il metodo del saldo decrescente, AMMORT.VAR utilizza un tasso fisso per tutta la vita del bene, dato da:
      [math]\displaystyle{ Rate~=~Factor~\times~\frac{1}{Life} }[/math]
    • L'ammortamento in ciascun periodo per il metodo del “saldo decrescente” è calcolato come:
      [math]\displaystyle{ \text{MIN}(Book~value \times Rate; Book~value~-~Salvage) }[/math]
      dove Valore contabile si riferisce al valore del bene all'inizio del periodo, che viene calcolato come Costo meno le spese di ammortamento totali fino ad oggi.
    • L'ammortamento “a quote costanti” per ciascun periodo è calcolato come:
      [math]\displaystyle{ \frac{Book~value~–~Salvage}{Periods~remaining} }[/math]
    • Per ulteriori informazioni di base sull'ammortamento, visitare la pagina Ammortamento di Wikipedia.

    Esempi:

    Notate che la formattazione dei valori restituiti forniti negli esempi seguenti potrebbe presupporre la localizzazione inglese (USA).

    Esempio semplice con più chiamate a AMMORT.VAR

    La tabella seguente illustra il comportamento della funzione AMMORT.VAR.

    Dati di esempio per la funzione AMMORT.VAR
    A B C D E F G H I J
    1 Costo: 1200 Inizio Fine AMMORT AMMORT.VAR
    (NessunCambio)         		AMMORT.VAR
    (Cambio)         		Differenza
    (NessunCambio)         		Differenza
    (Cambio)
    2 Valore residuo: 200 0 1 $257,14 $257,14 $257,14 $942,86 $942,86
    3 Vita utile: 7 1 2 $202,04 $202,04 $202,04 $740,82 $740,82
    4 Fattore: 1,5 2 3 $158,75 $158,75 $158,75 $582,07 $582,07
    5 3 4 $124,73 $124,73 $124,73 $457,34 $457,34
    6 4 5 $98,00 $98,00 $98,00 $359,34 $359,34
    7 5 6 $77,00 $77,00 $79,67 $282,34 $279,67
    8 6 7 $60,50 $60,50 $79,67 $221,84 $200,00
    9
    10 Totale $978,16 $978,16 $1 000,00
    A B C D E F G H I J

    Lo scopo degli esempi nella tabella sopra è mostrare i risultati della funzione AMMORT.VAR insieme ai risultati corrispondenti della funzione AMMORT funzione per il confronto. La colonna F presenta i risultati della funzione AMMORT. La colonna G presenta i risultati della funzione AMMORT.VAR con l'argomento NessunCambio impostato su VERO. La colonna H presenta i risultati della funzione AMMORT.VAR con l'argomento NessunCambio impostato su FALSO.

    I vari intervalli di celle in questo foglio di calcolo contengono i dati come segue:

    • Le celle B1:B4 contengono valori per quattro degli argomenti passati nelle varie chiamate alle funzioni AMMORT e AMMORT.VAR delle celle F2:H8.
    • Ciascuna cella D2:D8 contiene un valore per l'argomento Inizio che viene passato alle due chiamate di funzione AMMORT.VAR nella stessa riga del foglio di calcolo. Questi valori non vengono utilizzati nelle chiamate alla funzione AMMORT.
    • Ciascuna cella E2:E8 contiene un valore per l'argomento End che viene passato alle due chiamate alla funzione AMMORT.VAR nella stessa riga del foglio di calcolo. Ogni valore viene anche passato come argomento Periodo alla chiamata della funzione AMMORT nella stessa riga del foglio di calcolo.
    • Le celle F2:F8 mostrano i risultati restituiti dalle sette chiamate alla funzione AMMORT. La cella F2 contiene la formula =AMMORT($B$1; $B$2; $B$3; $E2; $B$4); la cella F3 contiene la formula =AMMORT($B$1; $B$2; $B$3; $E3; $B$4); e così via.
    • Le celle G2:G8 mostrano i risultati restituiti dalle sette chiamate alla funzione AMMORT.VAR per le quali l'ammortamento viene sempre calcolato utilizzando il metodo del saldo decrescente, senza mai passare alla linea retta metodo. La cella G2 contiene la formula =AMMORT.VAR($B$1; $B$2; $B$3; $D2; $E2; $B$4; VERO()); la cella G3 contiene la formula =AMMORT.VAR($B$1; $B$2; $B$3; $D3; $E3; $B$4; VERO()); e così via.
    • Le celle H2:H8 mostrano i risultati restituiti dalle sette chiamate alla funzione AMMORT.VAR per le quali parte dell'ammortamento può essere calcolata utilizzando il metodo della linea retta. La cella H2 contiene la formula =AMMORT.VAR($B$1; $B$2; $B$3; $D2; $E2; $B$4; FALSO()); la cella H3 contiene la formula =AMMORT.VAR($B$1; $B$2; $B$3; $D3; $E3; $B$4; FALSO()); e così via.
    • Le celle F10:H10 mostrano l'ammortamento totale calcolato durante la vita del bene per ciascun caso.

    In questi risultati è possibile osservare le seguenti caratteristiche:

    • Tutti i valori nelle celle F2:F8 corrispondono ai valori corrispondenti nelle celle G2:G8. Come previsto, AMMORT e AMMORT.VAR generano gli stessi risultati quando a quest'ultimo non è mai consentito passare alla linea retta metodo di ammortamento.
    • Periodo 1. Tutte le chiamate di funzione restituiscono lo stesso valore, $257,14. Il metodo del “saldo decrescente” utilizza un tasso fisso dato da:
      [math]\displaystyle{ ~Factor \times \frac{1}{Life} = 1.5 \times \frac{1}{7} = 0,214286 }[/math]
      Pertanto l'ammortamento per questo periodo è 0,214286 × 1200 = 257,14. Tieni presente che per impostazione predefinita, i risultati sia di AMMORT che di AMMORT.VAR sono formattati come valuta.
    • Periodo 2. Il valore dell'asset all'inizio di questo periodo è 1200 - 257,14 = 942,86. Pertanto l'ammortamento per questo periodo è 0,214286 × 942,86 = 202,04.
    • Periodo 3. Il valore dell'asset all'inizio di questo periodo è 942,86 - 202,04 = 740,82 . Pertanto l'ammortamento per questo periodo è 0,214286 × 740,82 = 158,75.
    • Periodo 4. Il valore dell'asset all'inizio di questo periodo è 740,82 - 158,75 = 582,07 . Pertanto l'ammortamento per questo periodo è 0,214286 × 582,07 = 124,73.
    • Periodo 5. Il valore dell'asset all'inizio di questo periodo è 582,07 - 124,73 = 457,34 . Pertanto l'ammortamento per questo periodo è 0,214286 × 457,34 = 98,00.
    • Periodo 6. In questo periodo vediamo AMMORT.VAR passare al metodo di ammortamento lineare dove può farlo, e questo è indicato dalla differenza tra i valori nelle celle G7 e H7. Il valore dell'asset all'inizio di questo periodo è 457,34 - 98,00 = 359,34. Pertanto l'ammortamento saldo decrescente per questo periodo è 0,214286 × 359,34 = 77,00. Tuttavia, l’ammortamento a quote costanti per questo periodo sarebbe dato da:
      [math]\displaystyle{ ~\frac {Cost~–~Salvage~–~Depreciation~so~far}{Periods~remaining} }[/math] =

      [math]\displaystyle{ ~\frac {1200-200-840,66}{2}=79,67 }[/math]
      come visualizzato nella cella H7. Il valore della linea retta (79,67) viene utilizzato perché è maggiore del valore del saldo decrescente (77,00).
    • Periodo 7. In quest'ultimo periodo di ammortamento, c'è ancora una differenza tra i valori nelle celle G8 e H8, con il valore calcolato della "linea retta" (79,67) mostrato nella cella H8.
    • Notate che l'ammortamento totale di 1 000,00 mostrato nella cella H10 è esattamente uguale alla differenza tra i valori di costo e di recupero e questa è una conseguenza dell'utilizzo del metodo linea retta per periodi di ammortamento successivi. Tuttavia, quando tutti i calcoli dell'ammortamento utilizzano il metodo del saldo decrescente, l'ammortamento totale potrebbe essere inferiore alla differenza tra i valori di costo e di recupero, come mostrato nelle celle F10 e G10.

    Ulteriori esempi

    Formula Descrizione Restituisce
    =AMMORT.VAR(35000; 7500; 36; 10; 20; 3; 1)

    Calcola l'ammortamento del saldo decrescente per un bene che inizialmente costa 35000 unità monetarie e ha un valore di recupero di 7500 unità monetarie. La vita utile del bene è di tre anni, con ammortamento da effettuarsi in 36 periodi mensili. L'ammortamento deve essere calcolato dal mese 10 al mese 20, utilizzando un fattore di ammortamento pari a 3. L'argomento finale è un valore numerico diverso da zero e quindi AMMORT.VAR non dovrebbe mai passare all'ammortamento a linea retta.

    		$7 161,64
    =AMMORT.VAR(35000; 7500; 36; 10; 20)

    Calcola l'ammortamento del saldo decrescente per un bene che inizialmente costa 35000 unità monetarie e ha un valore di recupero di 7500 unità monetarie. La vita utile del bene è di tre anni, con ammortamento da effettuarsi in 36 periodi mensili. L'ammortamento deve essere calcolato dal mese 10 al mese 20, utilizzando il fattore di ammortamento predefinito 2. L'argomento finale viene omesso, in modo che AMMORT.VAR possa passare all'ammortamento a linea continua quando appropriato.

    		$8 603,80
    =AMMORT.VAR(35000; 7500; 36; 10,5; 20,5)

    Calcola l'ammortamento del saldo decrescente per un bene che inizialmente costa 35000 unità monetarie e ha un valore di recupero di 7500 unità monetarie. La vita utile del bene è di tre anni, con ammortamento da effettuarsi in 36 periodi mensili. L'ammortamento deve essere calcolato dal mese 10,5 al mese 20,5, utilizzando il fattore di ammortamento predefinito 2. L'argomento finale viene omesso, in modo che AMMORT.VAR possa passare all'ammortamento a linea continua quando appropriato. Tieni presente che la formula =AMMORT.VAR(35000; 7500; 36; 10,5; 15,5) restituisce $4 776,02 e la formula =AMMORT.VAR(35000; 7500; 36; 15,5; 20,5); sommando nuovamente questi due valori si ottiene $8 364,81.

    		$8 364,81

    Funzioni di LibreOffice correlate:

    AMMORT.DEGR

    AMMORT.PER

    AMMORT.FISSO

    AMMORT

    AMMORT.COST

    AMMORT.ANNUO

    Standard ODF:

    Section 6.12.50, part 2

    Funzioni equivalenti (o simili) di Excel:

    VDB


    Retrieved from "https://wiki.documentfoundation.org/index.php?title=Documentation/Calc_Functions/VDB/it&oldid=772482"