Documentatie/Calc-functies/VDB

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/VDB and the translation is 100% complete.
    Other languages:

    Functienaam:

    VDB

    Categorie:

    Financieel

    Samenvatting:

    Berekent de afschrijving van een bezit voor een willekeurig tijdsinterval, voornamelijk gebaseerd op een methode voor degressieve afschrijving met variabele rente. (VDB is een acroniem voor Variable Declining Balance). Deze methode berekent de afschrijving op basis van de huidige boekwaarde van het bezit (in plaats van de oorspronkelijke kostprijs) en deze neemt af van de ene periode naar de andere. Dit leidt ertoe dat de afschrijving in eerdere perioden groter is en in latere perioden lager.

    In tegenstelling tot de DDB-functie, die dezelfde methode voor degressieve variabel tarief gebruikt, VDB biedt als volgt extra flexibiliteit:

    • Met VDB kan de gebruiker de afschrijvingstijd definiëren als een begin- en eindperiode binnen de gebruiksduur van het bezit. De begin- en eindperiode kunnen gedeeltelijke delen hebben.
    • VDB biedt een optie waarmee het bezit in eerste instantie kan worden afgeschreven met behulp van de degressieve methode met variabele rente en overschakelt naar lineaire afschrijving wanneer wordt berekend dat deze hoger is dan de degressieve afschrijving.

    Syntaxis:

    VDB(Kosten; Restwaarde; LD; Begin; Eind[; FA[; GeenWissel]])

    Retourneert:

    Retourneert een niet-negatief reëel getal, dat de afschrijving is van het bezit gedurende een opgegeven tijdsinterval. Het geretourneerde getal is in dezelfde valuta-eenheid als de opgegeven kosten- en restwaarden en wordt standaard opgemaakt in een landafhankelijke valuta-indeling.

    Argumenten:

    Kosten is een niet-negatief reëel getal of een verwijzing naar een cel die dat getal bevat, wat de kosten of waarde is van het activum vóór afschrijving.

    Restwaarde is een niet-negatief reëel getal, of een verwijzing naar een cel die dat getal bevat, wat de restwaarde is van het bezit aan het einde van zijn afgeschreven levensduur. Restwaarde moet in dezelfde valuta-eenheden zijn als Kosten.

    LD is een niet-negatief reëel getal of een verwijzing naar een cel die dat getal bevat, dat het aantal perioden definieert waarover het bezit wordt afgeschreven.

    Begin is een niet-negatief reëel getal of een verwijzing naar een cel die dat getal bevat, dat aangeeft op welk punt in de levensduur van het item VDB moet beginnen met afschrijving berekenen. Begin moet in dezelfde tijdseenheid zijn als LD.

    Eind is een niet-negatief reëel getal of een verwijzing naar een cel die dat getal bevat, dat het punt in de levensduur van het item specificeert waarop VDB moet eindigen met afschrijving berekenen. Eind moet dezelfde tijdseenheid hebben als LD en Begin.

    FA is een positief reëel getal of een verwijzing naar een cel die dat getal bevat, dat de afschrijvingsfactor specificeert die moet worden gebruikt voor de variabele rente degressieve methode. Als er geen waarde is opgegeven, is de standaardwaarde 2,0. Als FA = 2, dan gebruikt VDB de dubbele degressieve methode. Als FA = 3, dan gebruikt VDB de driedubbele degressieve methode.

    GeenWissel is een logische waarde of een verwijzing naar een cel die een logische waarde bevat, die bepaalt of VDB in staat is om over te schakelen naar lineaire afschrijving wanneer dat is groter dan de degressieve afschrijving. Als GeenWissel is weggelaten of ingesteld op 0 of is ingesteld op ONWAAR, schakelt VDB automatisch over naar lineaire afschrijving wanneer dat groter is dan de degressieve afschrijving. Als GeenWissel is ingesteld op een andere waarde dan nul of is ingesteld op WAAR, schakelt VDB nooit over naar lineaire afschrijving.

    • Als een argument niet-numeriek is, retourneert VDB als foutcode #WAARDE!
    • De functie retourneert als foutcode Ongeldig argument (Fout:502) in elk van de volgende omstandigheden:
      • Kosten < 0.
      • Restwaarde > Kosten.
      • FA ≤ 0.
      • Begin < 0.
      • Eind > LD.
      • Eind < Begin.

    Aanvullende details:

    • Om de afschrijving te berekenen met behulp van de degressieve methode, gebruikt VDB een vast percentage gedurende de levensduur van het bezit, gegeven door:
      [math]\displaystyle{ Rente~=~FA~\times~\frac{1}{LD} }[/math]
    • De afschrijving in elke periode voor de degressieve methode wordt berekend als:
      [math]\displaystyle{ \text{MIN}(Boekwaarde \times Rente; Boekwaarde - Restwaarde) }[/math]
      waarbij Boekwaarde verwijst naar de waarde van het bezit aan het begin van de periode, die wordt berekend als Kosten verminderd met de totale afschrijvingskosten tot nu toe.
    • De lineaire afschrijving voor elke periode wordt berekend als:
      [math]\displaystyle{ \frac{Boekwaarde~–~Restwaarde}{Resterende perioden} }[/math]
    • Ga voor meer achtergrondinformatie over afschrijving naar de pagina Depreciation op Wikipedia.

    Voorbeelden:

    Houd er rekening mee dat de opmaak van de geretourneerde waarden die in de volgende voorbeelden worden gegeven, kan uitgaan van de landinstelling Engels (VS).

    Eenvoudig voorbeeld met meerdere aanroepen naar VDB

    De volgende tabel illustreert het gedrag van de functie VDB.

    Voorbeeldgegevens voor functie VDB
    A B C D E F G H I J
    1 Kosten: 1200 Begin Eind DDB VDB
    (GeenWissel)
    VDB
    (Wissel)
    Verschil
    (GeenWissel)
    Verschil
    (Wissel)
    2 Restwaarde: 200 0 1 $257,14 $257,14 $257,14 $942,86 $942,86
    3 LD: 7 1 2 $202,04 $202,04 $202,04 $740,82 $740,82
    4 FA: 1,5 2 3 $158,75 $158,75 $158,75 $582,07 $582,07
    5 3 4 $124,73 $124,73 $124,73 $457,34 $457,34
    6 4 5 $98,00 $98,00 $98,00 $359,34 $359,34
    7 5 6 $77,00 $77,00 $79,67 $282,34 $279,67
    8 6 7 $60,50 $60,50 $79,67 $221,84 $200,00
    9
    10 Totaal $978,16 $978,16 $1.000,00
    A B C D E F G H I J

    Het doel van de voorbeelden in de bovenstaande tabel is om de resultaten van de VDB-functie weer te geven naast de overeenkomstige resultaten van de DDB functie ter vergelijking. Kolom F presenteert de resultaten van de functie DDB. Kolom G presenteert resultaten van de functie VDB met het argument GeenWissel ingesteld op WAAR. Kolom H presenteert de resultaten van de functie VDB met het argument GeenWissel ingesteld op ONWAAR.

    De verschillende celbereiken in dit werkblad bevatten de volgende gegevens:

    • Cellen B1:B4 bevatten waarden voor vier van de argumenten die zijn doorgegeven in de verschillende DDB en VDB}} functieaanroepen van cellen F2:H8.
    • Cellen D2:D8 bevatten elk een waarde voor het argument Begin die wordt doorgegeven aan de twee VDB functieaanroepen in dezelfde werkbladrij. Deze waarden worden niet gebruikt bij het aanroepen van de functie DDB.
    • Cellen E2:E8 bevatten elk een waarde voor het argument Eind die wordt doorgegeven aan de twee VDB functieaanroepen in dezelfde werkbladrij. Elke waarde wordt ook doorgegeven als het argument Periode aan de DDB functieaanroep in dezelfde werkbladrij.
    • Cellen F2:F8 tonen de resultaten die worden geretourneerd door de zeven DDB functieaanroepen. Cel F2 bevat de formule =DDB($B$1; $B$2; $B$3; $E2; $B$4); cel F3 bevat de formule =DDB($B$1; $B$2; $B$3; $E3; $B$4); enzovoort.
    • De cellen G2:G8 tonen de resultaten die worden geretourneerd door de zeven VDB functie-aanroepen waarvoor de afschrijving altijd wordt berekend met behulp van de degressieve methode, waarbij nooit wordt overgeschakeld naar de lineaire methode. Cel G2 bevat de formule =VDB($B$1; $B$2; $B$3; $D2; $E2; $B$4; WAAR()); cel G3 bevat de formule =VDB($B$1; $B$2; $B$3; $D3; $E3; $B$4; WAAR()); enzovoort.
    • Cellen H2:H8 tonen de resultaten die worden geretourneerd door de zeven VDB functieaanroepen waarvoor een deel van de afschrijving kan worden berekend met behulp van de lineaire methode. Cel H2 bevat de formule =VDB($B$1; $B$2; $B$3; $D2; $E2; $B$4; ONWAAR()); cel H3 bevat de formule =VDB($B$1; $B$2; $B$3; $D3; $E3; $B$4; ONWAAR()); enzovoort.
    • Cellen F10:H10 tonen de totale afschrijving berekend over de levensduur van het bezit voor elk geval.

    In deze resultaten zijn de volgende kenmerken te zien:

    • Alle waarden in cellen F2:F8 komen overeen met de overeenkomstige waarden in cellen G2:G8. Zoals verwacht genereren DDB en VDB dezelfde resultaten wanneer de laatstgenoemde mag nooit overstappen op de lineaire afschrijvingsmethode.
    • Periode 1. Alle functieaanroepen retourneren dezelfde waarde, $257,14. De degressieve methode gebruikt een vast tarief dat wordt gegeven door:
      [math]\displaystyle{ ~FA \times \frac{1}{LD} = 1.5 \times \frac{1}{7} = 0,214286 }[/math]
      De afschrijving voor deze periode is 0,214286 × 1200 = 257,14. Merk op dat standaard de resultaten van zowel DDDDB en VDB zijn geformatteerd als valuta.
    • Periode 2. De waarde van het bezit aan het begin van deze periode is 1200 - 257,14 = 942,86. Daarom is de afschrijving voor deze periode 0,214286 × 942,86 = 202,04.
    • Periode 3. De waarde van het bezit aan het begin van deze periode is 942,86 - 202,04 = 740,82. Daarom is de afschrijving voor deze periode 0,214286 × 740,82 = 158,75.
    • Periode 4. De waarde van het bezit aan het begin van deze periode is 740,82 - 158,75 = 582,07. Daarom is de afschrijving voor deze periode 0,214286 × 582,07 = 124,73.
    • Periode 5. De waarde van het bezit aan het begin van deze periode is 582,07 - 124,73 = 457,34. Daarom is de afschrijving voor deze periode 0,214286 × 457,34 = 98,00.
    • Periode 6. In deze periode zien we VDB overschakelen naar de lineaire afschrijvingsmethode waar dit kan en dit wordt aangegeven door het verschil tussen de waarden in cellen G7 en H7. De waarde van het bezit aan het begin van deze periode is 457,34 - 98,00 = 359,34. Daarom is de degressieve afschrijving voor deze periode 0,214286 × 359,34 = 77,00. De lineaire afschrijving voor deze periode zou echter worden gegeven door:
      [math]\displaystyle{ ~\frac {Kosten~–~Restwaarde~–~Afschrijving~tot~tot dusver}{Perioden~resterend} }[/math] =

      [math]\displaystyle{ ~\frac {1200-200-840,66}{2}=79,67 }[/math]
      zoals weergegeven in cel H7. De waarde van de lineaire waarde (79,67) wordt gebruikt omdat deze groter is dan de waarde van het degressieve waarde (77,00).
    • Periode 7. In deze laatste afschrijvingsperiode is er weer een verschil tussen de waarden in de cellen G8 en H8, waarbij de berekende lineaire waarde (79,67) wordt weergegeven in cel H8.
    • Merk op dat de totale afschrijving van 1.000,00 weergegeven in cel H10 exact gelijk is aan het verschil tussen de kostprijs en de restwaarde en dit is een gevolg van het gebruik van de lineaire methode voor latere afschrijvingsperioden. Wanneer alle afschrijvingsberekeningen echter de degressieve methode gebruiken, kan de totale afschrijving kleiner zijn dan het verschil tussen de kostprijs en de restwaarde, zoals weergegeven in de cellen F10 en G10.

    Extra voorbeelden

    Formule Beschrijving Retourneert
    =VDB(35000; 7500; 36; 10; 20; 3; 1)

    Berekent de degressieve afschrijving voor een bezit dat aanvankelijk 35000 valuta-eenheden kostte en een restwaarde heeft van 7500 valuta-eenheden. De gebruiksduur van het bezit is drie jaar en de afschrijving vindt plaats in 36 maandelijkse perioden. De afschrijving moet worden berekend van maand 10 tot maand 20, met een afschrijvingsfactor van 3. Het laatste argument is een numerieke waarde die niet gelijk is aan nul en daarom mag VDB nooit overschakelen naar lineaire afschrijving.

    $7.161,64
    =VDB(35000; 7500; 36; 10; 20)

    Berekent de degressieve afschrijving voor een bezit dat aanvankelijk 35000 valuta-eenheden kostte en een restwaarde heeft van 7500 valuta-eenheden. De gebruiksduur van het bezit is drie jaar en de afschrijving vindt plaats in 36 maandelijkse perioden. De afschrijving moet worden berekend van maand 10 tot maand 20, gebruikmakend van de standaard afschrijvingsfactor 2. Het laatste argument wordt weggelaten, zodat VDB indien nodig kan overschakelen naar lineaire afschrijving.

    $8.603,80
    =VDB(35000; 7500; 36; 10,5; 20,5)

    Berekent de degressieve afschrijving voor een bezit dat aanvankelijk 35000 valuta-eenheden kostte en een restwaarde heeft van 7500 valuta-eenheden. De gebruiksduur van het bezit is drie jaar en de afschrijving vindt plaats in 36 maandelijkse perioden. De afschrijving moet worden berekend van maand 10,5 tot 20,5, gebruikmakend van de standaard afschrijvingsfactor 2. Het laatste argument wordt weggelaten, zodat VDB indien nodig kan overschakelen naar lineaire afschrijving. Merk op dat de formule =VDB(35000; 7500; 36; 10,5; 15,5) $4.776,02 retourneert en de formule =VDB(35000; 7500; 36; 15,5; 20,5) retourneert $3.588,79; het opnieuw optellen van deze twee waarden levert $8.364,81 op.

    $8.364,81

    Gerelateerde LibreOffice-functies:

    AMORDEGRC

    AMORLINC

    DB

    DDB

    LIN.AFSCHR

    SYD

    ODF standaard:

    Sectie 6.12.50, deel 2

    Gerelateerde (of gelijkwaardige) Excel-functies:

    VDB