RECHERCHE

From The Document Foundation Wiki
Jump to: navigation, search


Renvoie une valeur d'une table large d'une cellule unique, à une position trouvée par la recherche dans une autre table.

Syntaxe

RECHERCHE(valeur_recherchée; table_recherche; table_résultat)

valeur_recherchée est une valeur (nombre, texte ou valeur logique) à rechercher dans une ligne unique ou une plage de colonne/matrice unique table_recherche. table_recherche doit être triée, avec les nombres en ordre ascendants apparaissant avant les valeurs texte dans l'ordre alphabétique.
table_résultat est une plage/matrice de la même taille que table_recherche. RECHERCHE renvoie la valeur dans table_résultat à la position ou la correspondance a été trouvée dans table_recherche.
RECHERCHE décide d'où dans table_recherche valeur_recherchée va apparaître. S'il y a une correspondance exacte, c'est la position trouvée ; s'il y a plus d'une correspondance exacte, la position trouvée n'est pas nécessairement la position la plus à gauche/la plus haute. S'il n'y a pas de correspondance exacte, la position juste avant où valeur_recherchée doit apparaître est trouvée ; il résulte une erreur #N/A si cette position n'est pas dans table_recherche.
La correspondance est toujours insensible à la casse - le paramètre de casse dans la fenêtre de dialogue Outils - Options - LibreOffice Calc - Calcul ne s'applique pas.
Utilisation avancée :
Si expressions régulières est activé dans Outils - Options - LibreOffice Calc - Calcul , RECHERCHE trouvera les correspondances exactes en traitant valeur_recherchée comme une expression régulière. Cela n'a de sens et ne doit être utilisé que si vous souhaitez trouver des correspondances exactes uniques.
Si 'Critères de recherche = et <> doivent correspondre à des cellules entières' est activé dans la boîte de dialogue Outils - Options - LibreOffice Calc - Calcul, valeur_recherchée doit correspondre à tout le texte dans la cellule ; sinon, il peut juste correspondre à une partie du texte.

Exemples

Dans ces exemples, les cellules A1, B1, C1, D1, E1 contiennent 3, 5, chat, mat, matter, et les cellules A2, B2, C2, D2, E2 contiennent A, B, C, D, E.

Calc rechercheh exemple.png

RECHERCHE(3; A1:E1; A2:E2)

renvoie A. La cellule A1 correspond à 3. Le contenu de la cellule correspondante dans A2:E2 est renvoyé.

RECHERCHE(7; A1:E1; A2:E2)

renvoie B. 7 doit apparaître entre 5 et chat, ainsi la position à gauche est trouvée.

RECHERCHE(1; A1:E1; A2:E2)

renvoie #N/A. 1 doit apparaître avant 3 dans la ligne supérieure et il n'y a pas de position à gauche dans la table.

RECHERCHE("CHAT"; A1:E1; A2:E2)

renvoie C. La différence entre minuscule et majuscule est ignorée, ainsi CHAT correspond à chat.

RECHERCHE("mate"; A1:E1; A2:E2)

renvoie D. mate doit apparaître entre mat et matter, ainsi la position à gauche est trouvée.

Utilisation avancée : expressions régulières

RECHERCHE("ch.t"; A1:E1; A2:E2)

renvoie C si les expressions régulières sont activées (et #N/A sinon). Le point '.' signifie 'pour tout caractère unique' dans une expression régulière, ainsi ch.t correspond à chat.

RECHERCHE(".at"; A1:E1; A2:E2)

".at" correspond à la fois à chat and mat si les expressions régulières sont activées. Cela correspond aussi à matter si la correspondance aux lignes entières est désactivée. Il n'est pas possible de prédire quelle correspondance sera trouvée, ni quel résultat va être renvoyé. Utilisez les expressions régulières avec précaution.

Utilisation de la fonction RECHERCHE avec 2 arguments

Syntaxe de la fonction : RECHERCHE(valeur_recherchée; vecteur_recherche_résultat)

Il est possible d'utiliser un matrice bi-dimensionnelle comme vecteur_recherche_resultat.
Si la matrice contient plus de lignes que de colonnes, la recherche est verticale.
Si la matrice contient plus de colonnes que de lignes, la recherche est horizontale.
Si la matrice est carrée (même nombre de lignes et de colonnes), la recherche est verticale.

La recherche s'effectue sur la première ligne (colonne) de la matrice et renvoie la valeur de la dernière ligne (colonne).

Exemple :
RECHERCHE(5;A1:E2)

renvoie B. Le 5 est recherché sur la première ligne, la valeur correspondante sur la dernière ligne est B.

Remarques

  • La sensibilité à la casse est discutée sur l'i#71000
  • Dans Excel, toute valeur logique dans table_recherche doit apparaître après toute valeur texte. Dans Calc, les valeurs logiques sont supposées avoir les valeurs numérique 0 (FAUX) et 1 (VRAI).
  • La flexibilité et la puissance des expressions régulières et l'option pour désactiver la correspondance sur une ligne entière rend cette fonction très complexe. La façon la plus simple et sécurisée d'utiliser cette fonction est de désactiver les expressions régulières et d'activer la recherche sur une ligne entière.

Voir également

CHOSIR, RECHERCHEH, INDEX, EQUIV, DECALER, RECHERCHEV

PROBABILITE

Expressions régulières dans Calc

Fonctions classeur

Fonctions listées alphabétiquement, Fonctions listées par catégories

Heckert GNU white.svg

Content on this page is licensed under the Public Documentation License (PDL).