Documentatie/Calc-functies/SOM.MACHTREEKS

This page is a translated version of the page Documentation/Calc Functions/SERIESSUM and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

SOM.MACHTREEKS

Categorie:

Wiskundig

Samenvatting:

Berekent de som van de eerste termen van een oneindige machtreeks van de vorm:

[math]\displaystyle{ \sum_{n=0}^{\infty }a_nx^n }[/math]

x is de variabele en a_n is de coëfficiënt van de n^de term in de reeks.

Syntaxis:

SOM.MACHTREEKS(X; N; M; Coefficiënten)

Retourneert:

Retourneert een reëel getal dat de som is van de eerste termen van de gegeven machtreeks.

Argumenten:

X is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat is de variabele voor de machtreeks.

N is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat is de initiële macht.

M is een reëel getal of een verwijzing naar een cel die dat getal bevat, dat wil zeggen de toename tot de macht voor elke term.

Coëfficiënten geeft de verzameling reële getallen die als coëfficiënten voor de termen van de machtreeks moeten worden gebruikt. Het aantal opgegeven coëfficiënten definieert het aantal te berekenen termen (één term per coëfficiënt). Coëfficiënten moeten één van de volgende vormen aannemen:

Een eenvoudige verwijzing naar een celbereik dat reële getallen bevat (bijvoorbeeld A1:B9).
De naam van een benoemd bereik, bestaande uit cellen die reële getallen bevatten.
De naam van een databasebereik, bestaande uit cellen die reële getallen bevatten.
Een ingebedde matrix van reële getallen (bijvoorbeeld {1.2, 3.4, 5.6, 7.8}).

De volgende foutcondities kunnen optreden:

Als een van X, N of M niet-numeriek is, retourneert SOM.MACHTREEKS als fout #WAARDE!
SOM.MACHTREEKS genereert niet noodzakelijkerwijs een fout wanneer Coëfficiënten een reëel getal is of een verwijzing naar een enkele cel. Als het argument Coëfficiënten echter een tekenreeks tussen aanhalingstekens is of een verwijzing naar een enkele cel die een tekenreeks bevat, retourneert SOM.MACHTREEKS als fout #WAARDE!
Waar Coëfficiënten is opgegeven als een ingebedde matrix of een celbereik, worden items die tekstreeksen of spaties bevatten genegeerd.
Als X negatief is en ofwel N of M geen geheel getal zijn, dan retourneert SOM.MACHTREEKS als fout Ongeldig argument (Fout:502). Negatieve waarden kunnen niet worden verheven tot fractionele machten.
Als X en N beide gelijk zijn aan 0, dan retourneert SOM.MACHTREEKS als fout #WAARDE! 0 tot de macht 0 is niet gedefinieerd.

Aanvullende details:

Een machtreeks kan worden weergegeven als:

[math]\displaystyle{ \text{f}(x)=a_{0}x^{n}+a_{1}x^{n+m}+a_{2}x^{n+2m}+a_{3}x^{n+3m}+... }[/math]

waar:

x is de variabele.
a_n is de coëfficiënt van de n^de term in de reeks.
m is de toename die wordt toegepast op de macht voor elke term.

Bijvoorbeeld, de reeksuitbreiding van e^x is een veelvoorkomende machtreeks, met de formule:

[math]\displaystyle{ \text {e}^{x}=\sum_{n=0}^{\infty }\frac{x^n}{n!}=1+\frac{x}{1!}+\frac{x^2}{2!}+\frac{x^3}{3!}+\frac{x^4}{4!}+... }[/math]

Om de (bij benadering) waarde van e^x te vinden, kunnen we SOM.MACHTREEKS gebruiken en de argumenten als volgt instellen:

Stel X in op de kracht van e die u nodig hebt.
Stel N in op 0 (de eerste term in de reeks is een constante).
Stel M in op 1 (de macht van x wordt bij elke term in de reeks met 1 verhoogd).
Stel Coëfficiënten in op de waarden 1, [math]\displaystyle{ \frac{1}{1!} }[/math], [math]\displaystyle{ \frac{1}{2!} }[/math], < math>\frac{1}{3!}</math> en [math]\displaystyle{ \frac{1}{4!} }[/math]. Door vijf coëfficiënten te gebruiken, berekent SOM.MACHTREEKS de eerste vijf termen van de machtreeks.

Zie het gedeelte #Voorbeelden: hieronder voor meer voorbeelden van deze machtreeks.

Een ander voorbeeld van een veelvoorkomende machtreeks is die voor de trigonometrische sinus, met de formule:

[math]\displaystyle{ \text{sin}(x)=\sum_{n=0}^{\infty }(-1)^n \frac{x^{2n+1}}{(2n+1)!}=x-\frac{x^3}{3!}+\frac{x^5}{5!}-\frac{x^7}{7!}+... }[/math]

Om de (geschatte) waarde van sin(x) te vinden, kunnen we SOM.MACHTREEKS gebruiken en de argumenten als volgt instellen:

Stel X in op de hoek in radialen waarvoor u de sinus wilt berekenen.
Stel N in op 1 (de eerste term in de reeks is een x¹ term).
Stel M in op 2 (de macht van x wordt bij elke term in de reeks met 2 verhoogd).
Stel Coëfficiënten in op de waarden 1, [math]\displaystyle{ -\frac{1}{3!} }[/math], [math]\displaystyle{ \frac{1}{5!} }[/math], en [math]\displaystyle{ -\frac{1}{7!} }[/math]. Door gebruik te maken van vier coëfficiënten zal SOM.MACHTREEKS de eerste vier termen van de machtreeks berekenen.

Zie het gedeelte #Voorbeelden: hieronder voor meer voorbeelden van deze machtreeks.

Voorbeelden:

Basisvoorbeelden

Formule	Beschrijving	Retourneert
=SOM.MACHTREEKS(2; 0; 1; {1; 2; 3})	Hier berekent de functie [math]\displaystyle{ 1+2x+3x^2 }[/math], waarbij x=2.	17
=SOM.MACHTREEKS(0,5; 1; 2; {1; 1; 1})	Hier berekent de functie [math]\displaystyle{ x+x^3+x^5 }[/math], waarbij x=0,5.	0,65625

Bereken de geschatte waarde van e^x

Gebruik de bovenstaande beschrijving van de e^x macht-serie om gegevens in uw werkblad in te stellen in overeenstemming met de volgende tabel.

	A	B
1	X	1
2	N	0
3	M	1
4	Coefficiënt[0]	1
5	Coefficiënt[1]	1
6	Coefficiënt[2]	0,5
7	Coefficiënt[3]	0,166666666666667
8	Coefficiënt[4]	0,041666666666667

Formule	Beschrijving	Retourneert
=SOM.MACHTREEKS(B1; B2; B3; B4:B8) waarbij de cellen B1 tot en met B8 de hierboven vermelde getallen bevatten.	Hier berekent de functie een geschatte waarde voor e. Het gebruik van meer termen van de machtreeks zou een betere benadering van de werkelijke waarde geven (2,7182818284...).	2,70833333333333
=SOM.MACHTREEKS(0,5; B2; B3; B4:B8) waarbij de cellen B2 tot en met B8 de bovenstaande getallen bevatten.	Hier berekent de functie een geschatte waarde voor de vierkantswortel van e. Het gebruik van meer termen van de machtreeks zou een betere benadering van de werkelijke waarde geven (1,6487212707...).	1,6484375

Bereken de geschatte waarde van sin(x)

Gebruik de beschrijving van de sin(x) machtreeks die hierboven is gegeven en stel gegevens in uw werkbladin in overeenstemming met de volgende tabel.

	A	B
1	X	1,0471975511966
2	N	1
3	M	2
4	Coefficiënt[0]	1
5	Coefficiënt[1]	−0,166666666666667
6	Coefficiënt[2]	0,008333333333333
7	Coefficiënt[3]	−0,000198412698413

Formule	Beschrijving	Retourneert
=SOM.MACHTREEKS(B1; B2; B3; B4:B7) waarbij de cellen B1 tot en met B7 de hierboven vermelde getallen bevatten.	Hier berekent de functie een geschatte waarde voor sin(π/3). Het gebruik van meer termen van de machtreeks zou een betere benadering van de werkelijke waarde geven (0,866025403784439...).	0,866021271656373
=SOM.MACHTREEKS(0,5; B2; B3; B4:B7) waarbij de cellen B2 tot en met B7 de bovenstaande getallen bevatten.	Hier berekent de functie een geschatte waarde voor sin(0,5). Het gebruik van meer termen van de machtreeks zou een betere benadering van de werkelijke waarde geven (0,479425538604203...).	0,479425533234127

Gerelateerde LibreOffice-functies:

Geen

ODF standaard:

Section 6.16.53, part 2

Gerelateerde (of gelijkwaardige) Excel-functies:

SERIESSUM