Documentation/Calc Functions/SUM.FLERE.HVIS

From The Document Foundation Wiki
Jump to: navigation, search
This page is a translated version of the page Documentation/Calc Functions/SUMIFS and the translation is 100% complete.

Other languages:
dansk • ‎English

Funktionsnavn:

SUM.FLERE.HVIS

Kategori:

Matematisk

Resume:

Returnerer summen af cellernes værdi i et område, der opfylder flere kriterier i flere områder.

Syntaks:

SUM.FLERE.HVIS(Sum-område; Område 1; Kriterium 1[; Område 2; Kriterium 2][; … ; [Område 127; Kriterium 127]])

Returnerer:

Returnerer et reelt tal, som er summen af de områder, der opfylder deres tilsvarende kriterier.

Argumenter:

Sum-område (obligatorisk) Det er et celleområde, navnet på en navngivet område eller etiketten på en kolonne eller række, der indeholder værdier til beregning af summen.

Criterium 1 (obligatorisk) Et strengudtryk, der repræsenterer en logisk betingelse, eller en cellereference til et sådant udtryk. Udtrykket kan indeholde tekst, tal, regulære udtryk eller jokertegn (hvis det er aktiveret under beregningsindstillinger).

Område 2 (Valgfri) Område 2 og alle de følgende betyder det samme som Område 1.

Kriterium 2 (valgfri) Kriterium 2 og alle følgende betyder det samme som Kriterium 1.

  • Sum-område og område 1, område 2... skal have den samme størrelse, eller returnerer funktionen en værdifejl.
  • Funktionen kan have op til 255 argumenter, hvilket betyder, at du kan specificere 127 kriterieområder og deres kriterier.

Yderligere oplysninger:

  • Søgningen understøtter jokertegn eller regulære udtryk. Når regulære udtryk er aktiveret, kan du for eksempel indtaste "alle.*", for at finde den første forekomst af "alle" fulgt af vilkårlige tegn. Hvis du vil søge efter en tekst, der også er et regulært udtryk, skal du enten sætte tegnet "\" foran hvert tegn eller indramme teksten med \Q...\E.

Du kan slå den automatiske evaluering af jokertegn eller regulære udtryk til og fra under Funktioner > Indstillinger > LibreOffice Calc > Beregn.

  • Under brug af funktioner, hvor et eller flere argumenter er søgekriteriestrenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere kriteriestrengene til tal. ".0" bliver fx konverteret til 0.0 osv. Hvis det lykkes, bliver matchet ikke et match med et regulært udtryk, men et numerisk match. Et skift til en lokalisering, hvor decimalskilletegnet ikke er punktum, får konverteringen til regulært udtryk til at virke. Til at gennemtvinge evalueringen af det regulære udtryk i stedet for et numerisk udtryk bruger du et udtryk, der ikke fejllæses som numerisk som fx ".[0]", ".\0" eller "(?i).0".
  • Den logiske relation mellem kriterierne kan defineres som et logisk OG (konjunktion). Med andre ord: hvis og kun hvis alle givne kriterier opfyldes, tages en værdi fra den tilsvarende celle af den givne Sum-område til beregningen.
  • Hvis en celle indolder SAND, behandles den som 1; hvis en celle indeholder FALSK – som 0 (nul).

Eksempler:

Betragt denne tabel

A B C
1 Produktnavn Salg Indtægt
2 pencil 20 65
3 pen 35 85
4 notebook 20 190
5 bog 17 180
6 penalhus nej nej

I alle eksempler herunder indeholder beregningområderne række 6, som ignoreres, fordi den indeholder tekst.

Enkel brug

Formel Beskrivelse Returnerer
=SUM.FLERE.HVIS(B2:B6;B2:B6;">=20") Beregner summen af værdier i området B2:B6, som er større end eller lig med 20. Her opfylder den femte række ikke kriteriet. 75
=SUM.FLERE.HVIS(C2:C6;B2:B6;">=20";C2:C6;">70") Beregner summen af værdier i området C2:C6, som er større end 70 og svarer til celler i området B2:B6, som er større end eller lig med 20. Her opfylder den anden og den femte række ikke mindst et kriterium. 275

Med regulære udtryk og indlejrede funktioner

Formel Beskrivelse Returnerer
=SUM.FLERE.HVIS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Beregner summen af værdier i området C2:C6, som svarer til alle værdier i området B2:B6 undtaget dets minimum og maksimum. Her opfylder den tredje og femte række mindst et kriterium. || 255

=SUM.FLERE.HVIS(C2:C6;A2:A6;"pen.*";B2:B6;"<"&MAX(B2:B6))

Beregner summen af værdier i området C2:C6, som svarer til alle værdier i området A2:A6, der begynder med "pen" og til alle celler i området B2:B6 undtagen dets maksimum. Her opfylder kun den anden række alle kriterier. || 65

Reference til en celle som kriterium

Formel Beskrivelse Returnerer =SUM.FLERE.HVIS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6)), hvor E2 = pen Hvis du har brug for let at ændre et kriterium, vil du måske bestemme det i en separat celle og bruger en reference til denne celle som betingelse i funktionen SUM.FLERE.HVIS. her er linket til cellen erstattet med dens indhold. 65

Flere eksempler

Find flere eksempler ved at downloade og se dette For more examples, download and view this Calc-regneark.

Beslægtede LibreOffice-funktioner:

SUM

SUM.HVIS

MIDDEL.FLERE.HVIS

TÆL.FLERE.HVIS

MIN.FLERE.HVIS

MAKSHVISER

ODF standard:

Section 6.16.63, part 2

Tilsvarende Excel-funktion:

SUM.FLERE.HVIS