Documentación/Funciones de Calc/SUMAR.SI.CONJUNTO

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/SUMIFS and the translation is 98% complete.
    Outdated translations are marked like this.


    Nombre de la función:

    SUMAR.SI.CONJUNTO

    Categoría:

    Matemáticas

    Resumen:

    Calcula la suma de un conjunto de números en un rango de celdas, con las celdas que se agregarán determinadas usando múltiples criterios. La principal diferencia entre SUMAR.SI.CONJUNTO y la función SUMAR.SI de Calc, es que esta último se limita a evaluar un solo criterio.

    Los criterios pasados a SUMAR.SI.CONJUNTO pueden utilizar comodines o expresiones regulares.

    Sintaxis:

    SUMAR.SI.CONJUNTO(SumRange; Range 1; Criterion 1[; Range 2; Criterion 2[; … [; Range 127; Criterion 127]]])

    Devuelve:

    Devuelve un número real, que es el resultado de sumar los números de las celdas correspondientes.

    Argumentos:

    Argumento de Rango de suma

    Rango de suma especifica las celdas que se van a sumar. Rango de suma toma generalmente una de las siguientes formas:

    • Una referencia a un rango de celdas (por ejemplo, A1:A25), que puede no utilizar el operador de concatenación de referencia (~).
    • El nombre de un rango con nombre.
    • El nombre de un rango de base de datos.

    Argumento de rango

    Rango 1 especifica el conjunto de celdas que se compararán con Criterio 1 y adopta una de las formas enumeradas para Rango de suma. Rango 1 debe tener las mismas dimensiones que Rango de suma.

    Rango 2, ..., Rango 127 tienen el mismo significado que Rango 1.

    Argumento del criterio

    Criterio 1 es el criterio para comparar con las celdas en Rango 1, o una celda que contiene ese criterio. El Criterio 1 puede tomar una de las siguientes formas:

    • Un número, como 34,5. Las fechas y los valores lógicos (VERDADERO o FALSO) se tratan como números.
    • Una expresión, como 2/3, RAIZ($D$1) o FECHA(2021; 11; 1).
    • Una cadena de texto, como "golf" o "<>10".

    SUMAR.SI.CONJUNTO busca celdas en Rango 1 que sean iguales a Criterio 1, a menos que Criterio 1 sea una cadena de texto que empieza con un comparador (>, <, > =, <=, = o <>). En el último caso SUMAR.SI.CONJUNTO compara las celdas en Rango 1 con el resto de la cadena de texto (interpretado como un número si es posible y como texto de lo contrario). Por ejemplo, la condición ">4,5" prueba si el contenido de cada celda es mayor que el número 4,5; la condición "<perro" prueba si el contenido de cada celda viene alfabéticamente antes del texto "perro" y la condición "< >2021-11-01" prueba si el contenido de cada celda no es igual a la fecha especificada.

    El Criterio 1 admite los siguientes comportamientos específicos:

    • La cadena "=" coincide con celdas vacías. Por ejemplo, la fórmula =SUMAR.SI.CONJUNTO(A1:A10; B1:B10; "=") devuelve la suma de todos los valores en el rango A1:A10 si todas las celdas en el rango B1:B10 están vacías. Tenga en cuenta que "=0" no coincide con las celdas vacías.
    • La cadena "<>" coincide con celdas que no están vacías. Por ejemplo, la fórmula =SUMAR.SI.CONJUNTO(A1:A10; C1:C10; "<>") devuelve la suma de todos los valores en el rango A1:A10 si no hay celdas vacías en el rango C1: C10.
    • Si el valor después del comparador <> no está vacío, entonces Criterio 1 coincide con cualquier contenido de celda excepto ese valor, incluidas las celdas vacías.

    Criterio 2, ..., Criterio 127 tienen el mismo significado que Criterio 1.

    Condiciones de error

    • Si algún rango de celdas pasado como argumento, contiene un operador de concatenación de referencia (~), SUMAR.SI.CONJUNTO mostrará un error de argumento no válido (Err:502).
    • Todos los rangos de celdas pasados como argumentos (Rango de suma y Rango 1, …, Rango 127) deben ocupar el mismo número de filas y el mismo número de columnas. Si ese no fuera el caso, SUMAR.SI.CONJUNTO mostrará un error de argumento no válido (Err:502).
    • Si los argumentos Rango n y Criterio n no se emparejan correctamente, SUMAR.SI.CONJUNTO mostrará un error de falta de variable (Err:511).

    Detalles adicionales:

    Detalles específicos de la función SUMAR.SI.CONJUNTO

    • La coincidencia predeterminada realizada por SUMAR.SI.CONJUNTO no distingue entre mayúsculas y minúsculas. Sin embargo, se puede realizar una coincidencia que distingue entre mayúsculas y minúsculas, cuando se usa una expresión regular al incluir un modificador de modo "(?-i)" dentro de la expresión regular, como se demuestra en uno de los ejemplos a continuación.
    • El comportamiento de SUMAR.SI.CONJUNTO se ve afectado por varias configuraciones disponibles en el cuadro de diálogo Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular (LibreOffice ▸ Preferencias ▸ LibreOffice Calc ▸ Calcular en macOS).
    1. Si la casilla de verificación está marcada para Los criterios de búsqueda = y <> deben aplicarse a celdas completas, entonces la condición "rojo" coincidirá solo con "rojo"; si no se marca, coincidirá con "rojo", "Fred", "red herring".
    2. Si la casilla de verificación está marcada para Habilitar comodines en fórmulas, la condición coincidirá con comodines; por ejemplo, "b?g" coincidirá con "bag", "beg", "big", "bog ", y "error".
    3. Si la casilla de verificación está marcada para Habilitar expresiones regulares en fórmulas, la condición coincidirá con expresiones regulares; por ejemplo, "r.d" coincidirá con "red", "rid" y "rod", mientras que "red.*" coincidirá con "red", "redraw" y "redden".
    4. La configuración de la casilla de verificación Sensible a mayúsculas y minúsculas no tiene ningún impacto en el funcionamiento de SUMAR.SI.CONJUNTO.


    Información general sobre las expresiones regulares de Calc

    Note pin.svg

    Nota:
    Para mayor comodidad, la información de esta subsección se repite en todas las páginas que describen funciones que manipulan expresiones regulares.

    • Una expresión regular es una cadena de caracteres que define un patrón de texto que debe coincidir. Se puede encontrar información general más detallada en la página Expresión regular de Wikipedia.
    • Las expresiones regulares se usan ampliamente en muchos dominios y hay varios procesadores de expresiones regulares disponibles. Calc utiliza el paquete de expresiones regulares de código abierto de los componentes internacionales para Unicode (ICU), consulte su documentación Regular Expressions para obtener más detalles, incluida una definición completa de la sintaxis de expresiones regulares ICU.
    • Además, el sistema de ayuda de LibreOffice proporciona una lista de expresiones regulares de alto nivel .
    • El motor de expresiones regulares de Calc es compatible con grupos de captura numerados, que permiten identificar y usar sub-intervalos dentro de una coincidencia dentro del texto de reemplazo. Los paréntesis se utilizan para agrupar componentes de una expresión regular y crear un grupo de captura numerado. Para insertar un grupo de captura en un texto de reemplazo, use la forma "$n", donde n es el número del grupo de captura.


    Información general sobre los comodines de Calc

    Los comodines son caracteres especiales que se pueden usar en cadenas de búsqueda que se pasan como argumentos a algunas funciones de Calc; también se pueden utilizar para definir criterios de búsqueda en el cuadro de diálogo Buscar y Reemplazar. El uso de comodines permite la definición de parámetros de búsqueda más avanzados con una sola cadena de búsqueda.

    Calc admite comodines o expresiones regulares como argumentos, según la configuración actual de la aplicación. De forma predeterminada, se admiten comodines en lugar de expresiones regulares.

    Para asegurarse de que los comodines sean compatibles, vaya a Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular y verifique si la opción Permitir comodines en las fórmulas está seleccionada. Tenga en cuenta que puede usar este cuadro de diálogo para cambiar a expresiones regulares eligiendo Permitir expresiones regulares en las fórmulas o elegir Ningún comodín ni expresión regular en las fórmulas.

    La siguiente tabla identifica los comodines que admite Calc.

    Calc wildcards
    Comodín Descripción
    ? (signo de interrogación) Coincide con cualquier carácter individual. Por ejemplo, la cadena de búsqueda "b?g" coincide con "bag" y "beg", pero no con "boog" o "mug".

    Tenga en cuenta que tampoco coincidirá con "bg", ya que "?" debe coincidir exactamente con un carácter. El comodín "?" no se corresponde con una coincidencia de cero caracteres.
    * (asterisco) Coincide con cualquier secuencia de caracteres, incluida una cadena vacía. Por ejemplo, la cadena de búsqueda "*cast" coincidirá con "cast", "forecast" y "outcast", pero no coincidirá con "forecaster" usando la configuración predeterminada de Calc.

    Si la opción Los criterios de búsqueda = y <> deben aplicarse a celdas enteras está deshabilitada en Herramientas ▸ Opciones ▸ LibreOffice Calc ▸ Calcular, al usar la cadena de búsqueda "*cast", la palabra "forecaster" será una coincidencia.
    ~ (tilde) Escapa (omite) el significado especial de un signo de interrogación, asterisco o tilde que sigue inmediatamente después del carácter de tilde.

    Por ejemplo, la cadena de búsqueda "why~?" coincide con "why?", pero no coincidirá con "why" ni "why~s".

    Las comparaciones con comodines no distinguen entre mayúsculas y minúsculas, por lo tanto, "A?" coincidirá tanto con "A1" como con "a1".

    Estos comodines se admiten tanto en Calc como en Microsoft Excel. Por lo tanto, si se necesita interoperabilidad entre las dos aplicaciones, opte por trabajar con comodines en lugar de expresiones regulares. Por el contrario, si la interoperabilidad no es necesaria, considere usar expresiones regulares para capacidades de búsqueda más potentes.

    Ejemplos:

    Ejemplos de ventas de papelería

    Considere la siguiente tabla, que muestra la información de ventas e ingresos de un pequeño proveedor de papelería. La cadena "N/D" se refiere a productos que no estaban disponibles para el suministro, durante el período cubierto por los datos.

    A B C
    1 Producto Ventas Ingresos
    2 Lápiz 20 $65
    3 Bolígrafo 35 $85
    4 Libreta 20 $190
    5 Libro 17 $180
    6 Estuche N/D N/D

    En todos los ejemplos basados en esta tabla, debe tenerse en cuenta que la fila 6 para estuches de lápices no contiene datos numéricos y, por lo tanto, nunca contribuirá al resultado de SUMAR.SI.CONJUNTO, independientemente de los criterios que se especifiquen.

    Fórmula Descripción Devuelve
    =SUMAR.SI.CONJUNTO(B2:B6; B2:B6; ">=20") Aquí la función suma los datos numéricos de "Ventas" mayores o iguales a 20. 75
    =SUMAR.SI.CONJUNTO(C2:C6; B2:B6; ">=20"; C2:C6; ">70") Aquí la función localiza entradas mayores o iguales a 20 en los datos de Ventas que también tienen un valor superior a $70 en los datos de Ingresos y suma las entradas numéricas correspondientes en los datos de Ingresos. $275
    =SUMAR.SI.CONJUNTO(C2:C6; B2:B6; ">"&MIN(B2:B6); B2:B6; "<"&MAX(B2:B6)) Aquí la función calcula la suma de las entradas numéricas en los datos de Ingresos que corresponden a todos los valores en los datos de Ventas excepto el mínimo y el máximo. $255
    =SUMAR.SI.CONJUNTO(C2:C6; A2:A6; "pen.*"; B2:B6; "<"&MAX(B2:B6)) Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. Aquí la función localiza entradas en los datos de Producto que empiezan con los caracteres "bolígrafo" y tienen un valor en los datos de Ventas que no es el máximo, y suma las entradas numéricas correspondientes en los datos de Ingresos. $65
    =SUMAR.SI.CONJUNTO(C2:C6; A2:A6; E2&".*"; B2:B6; "<"&MAX(B2:B6)) donde la celda E2 contiene la cadena "bolígrafo" (sin las comillas dobles). Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. Si necesita cambiar un criterio fácilmente, puede especificarlo en una celda separada y usar una referencia a esta celda en la condición de la función SUMAR.SI.CONJUNTO. Aquí se sustituye el enlace a la celda por su contenido, dando el mismo resultado que el ejemplo anterior. $65

    Ejemplos de venta de equipamiento deportivo

    Los ejemplos de esta subsección se basan en una pequeña base de datos de ventas de equipos deportivos, con los datos organizados como en la siguiente tabla.

    A B C D E
    1 Fecha Valor de las ventas Categoría Región Empleado/a
    2 2021-10-02 $1,508 Golf Este Hans
    3 2021-10-02 $410 Tennis Norte Kurt
    4 2021-10-02 $2,340 Navegación Sur Ute
    5 2021-10-03 $4,872 Tennis Este Brigitte
    6 2021-10-06 $3,821 Tennis Sur Fritz
    7 2021-10-06 $2,623 Tennis Este Fritz
    8 2021-10-07 $3,739 Golf Sur Fritz
    9 2021-10-08 $4,195 Golf Oeste Ute
    10 2021-10-10 $2,023 Golf Este Hans
    Fórmula Descripción Devuelve
    =SUMAR.SI.CONJUNTO(B2:B10; B2:B10; ">=4000") Aquí la función suma las entradas numéricas en los datos de Valor de ventas que son mayores o iguales a $4,000. Esta fórmula es equivalente a =SUMAR.SI(B2:B10; ">=4000") y =SUMAR.SI(B2:B10; ">=4000"; B2:B10). $9,067
    =SUMAR.SI.CONJUNTO(B2:B10; E2:E10; "ute") Aquí, la función localiza las entradas para Ute en los datos de Empleado y suma las entradas numéricas correspondientes a los datos de Valor de ventas. Esta fórmula es equivalente a =SUMAR.SI(E2:E10; "ute"; B2:B10) y esta reordenación de argumentos destaca una diferencia clave entre las dos funciones: Rango de suma que es el tercer argumento para SUMAR.SI y el primer argumento de SUMAR.SI.CONJUNTO. $6,535
    =SUMAR.SI.CONJUNTO(B2:B10; CategoryData; "golf") donde se ha creado el rango con nombre CategoríaDatos para cubrir el rango de celdas C2:C10. Aquí la función localiza las entradas para Golf en los datos de Categoría y suma las entradas numéricas correspondientes a los datos de Valor de ventas. $11,465
    =SUMAR.SI.CONJUNTO(B2:B10; D2:D10; F1; E2:E10; F2) donde las celdas F1 y F2 contienen las cadenas de texto ">=sur" y "ute" respectivamente (ambas sin las comillas dobles). Aquí, la función localiza las entradas para Sur y Oeste en los datos de Región, que también tienen Ute en los datos de Empleado y suma las entradas numéricas correspondientes a los datos de Valor de ventas. $6,535
    =SUMAR.SI.CONJUNTO(B2:B10; A2:A10; FECHA(2021; 10; 2); C2:C10; "tennis") Aquí, la función ubica las entradas para 2021-10-02 en la columna Fecha, que también tienen Tenis en los datos de Categoría y suma las entradas numéricas correspondientes a los datos de Valor de ventas. $410
    =SUMAR.SI.CONJUNTO(B2:B10; A2:A10; ">="&FECHA(2021; 10; 6); E2:E10; "<>"&E8) Aquí, la función ubica las entradas con fecha de 2021-10-06 o posterior en la columna "Fecha", que no tienen Fritz en los datos de "Empleado", y suma las entradas numéricas correspondientes a los datos de "Valor de ventas". $6,218
    =SUMAR.SI.CONJUNTO(B2:B10; C2:C10; "tennis"; D2:D10; "east"; E2:E10; "fritz") Aquí la función localiza las entradas que tienen Tenis en los datos de Categoría, Este en los datos de Región y Fritz en los datos de Empleado. Suma las entradas numéricas correspondientes a los datos de Valor de ventas. $2,623
    =SUMAR.SI.CONJUNTO(B2:B10; D2:D10; "????"; E2:E10; "*e") Este ejemplo solo funcionará como se describe aquí, si los comodines están habilitados. Aquí la función localiza las entradas de cuatro caracteres en los datos de Región (Este y Oeste) que también tienen una entrada en los datos de Empleado que termina con la letra "e" o "E" (Brigitte y ute). Suma las entradas numéricas correspondientes a los datos de Valor de ventas. $9,067
    =SUMAR.SI.CONJUNTO(B2:B10; C2:C10; "^t.*"; D2:D10; ".*h") Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. Aquí la función localiza las entradas para Tenis en los datos de Categoría que comienzan con la letra "t" o "T" (Tenis) que también tienen una entrada en los datos de Región que terminan con la letra " h" o "H" (Norte y Sur). Suma las entradas numéricas correspondientes a los datos de Valor de ventas. $4,231
    =SUMAR.SI.CONJUNTO(B2:B10; E2:E10; "(?-i)ute") Este ejemplo solo funcionará como se describe aquí, si las expresiones regulares están habilitadas. El modificador de modo "(?-i)" dentro de la expresión regular cambia a una coincidencia que distingue entre mayúsculas y minúsculas, por lo que no se encuentran entradas en los datos de "Empleado". Compare esto con el segundo ejemplo de esta tabla. $0

    Ejemplos adicionales:

    Para ver más ejemplos, descargue y vea este Hoja de cálculo de Calc.

    Funciones de LibreOffice relacionadas:

    PROMEDIO.SI.CONJUNTO

    CONTAR.SI.CONJUNTO

    SUMAR.SI

    Norma ODF:

    Sección 6.16.63, parte 2

    Funciones equivalentes de Excel:

    SUMIFS