Dokumentation/Calc Funktionen/VERBINDEN

    From The Document Foundation Wiki
    This page is a translated version of the page Documentation/Calc Functions/TEXTJOIN and the translation is 100% complete.
    Other languages:


    Funktionsname:

    VERBINDEN

    Kategorie:

    Text

    Zusammenfassung:

    Verbindet mehrere Zeichenketten zu einem einzigen Text und fügt Begrenzer zwischen den einzelnen Teilen ein.

    Die Funktion VERBINDEN ist verwandt mit den Funktionen TEXTKETTE und VERKETTEN, bietet aber zusätzlich die Möglichkeit, Begrenzer zwischen den einzelnen Zeichenketten einzufügen.

    Syntax:

    VERBINDEN(Begrenzer, überspringe Leer, Zeichenkette 1 [; Zeichenkette 2 [; … ;[ Zeichenkette 253]]])

    Rückgabewerte:

    Gibt die zusammengehängten Zeichenketten mit dem Begrenzer dazwischen als Text zurück.

    Argumente:

    Begrenzer ist eine Zeichenkette (in Anführungszeichen), eine Zahl, ein Zellbezug, ein Zellbereich oder eine Aufzählung (mit geschweiften Klammern '{' und '}'). Begrenzer gibt den Text an, der zwischen jeweils zwei Zeichenketten eingebaut werden soll.

    überspringe Leer gibt an, ob leere Zellen und/oder leere Zeichenketten eingesetzt (0 oder FALSCH) oder ignoriert werden (jeder andere Wert). Falls mit 0 oder FALSCH leere Zellen und/oder Zeichenketten eingebaut werden, dann kann der zurückgegebene Text aufeinanderfolgende Begrenzer beinhalten.

    Zeichenkette 1 ist eine Zeichenkette (in Anführungszeichen), eine Zahl, ein Zellbezug, ein Zellbereich oder eine Aufzählung (mit geschweiften Klammern '{' und '}'). Zeichenkette 1 gibt die erste Zeichenkette(n) an, die zusammengehängt werden sollen.

    Zeichenkette 2 bis Zeichenkette 253 sind ähnlich der Zeichenkette 1, geben aber die folgenden Zeichenketten an, die zusammengehängt werden sollen.

    • Falls der Begrenzer mehrere Zeichenketten angibt (z. Bsp. ein Zellbereich oder eine Aufzählung) muss die Anzahl der Begrenzer nicht unbedingt der Anzahl der zusammenzuhängenden Zeichenketten entsprechen. Falls mehr Begrenzer als Zeichenketten angegeben sind, werden nicht alle Begrenzer verwendet. Falls weniger Begrenzer als Zeichenketten angegeben sind, werden die Begrenzer zyklisch wiederverwendet.
    • Falls überspringe Leer nicht numerisch ist, dann meldet VERBINDEN einen #WERT!.
    • Wenn ein Zellbereich angegeben ist, werden die Zellen zeilenweise von oben nach unten abgearbeitet. Das gilt sowohl für den Begrenzer als auch für die Zeichenkette(n).
    • Die Länge des Rückgabetextes ist begrenzt auf 256 * (1024)2 Zeichen. Falls die angegebenen Argumente zu einem längeren Text führen, dann meldet VERBINDEN einen string overflow error (Fehler:513).

    Zusätzliche Informationen:

    Diese Funktion ist kein Erfordernis des ODF 1.2 aber ist kompatibel zur Funktion VERBINDEN aus Microsoft EXCEL.

    Beispiele:

    Formel Beschreibung Ergebnis
    =VERBINDEN(" "; 1; "Here"; "comes"; "the"; "sun") Hier hängt die Funktion die vier Argumente zusammen, getrennt durch jeweils ein Leerzeichen. In diesem Beispiel ist der exakte Wert des überspringe Leer Arguments unwichtig, weil es keine leeren Zeichenketten zusammenzuhängen gibt. Da kummt die Sunn.
    =VERBINDEN(B1; C1; D1; D2; D3; D4), wobei die Zelle B1 die Zeichenkette "-" enthält, die Zelle C1 enthält die Zahl 1 und die Zellen D1 bis D4 enthalten die Zeichenketten "Da", "kummt", "die" und "Sunn". Hier hängt die Funktion die vier Zeichenketten (angegeben über einen Zellbezug) zusammen, getrennt durch einen Bindestrich (auch über einen Zellbezug angegeben). In diesem Beispiel ist der exakte Wert des Arguments überspringe Leer (wieder über einen Zellbezug angegeben) unwichtig, da es keine leeren Zeichenketten zusammenzuhängen gibt. Da-kummt-die-Sunn
    =VERBINDEN(", "; 0; "John Doe"; ""; "23 High Street"; "Some Town"; "Some City") Hier hängt die Funktion die Zeichenketten zusammen, getrennt durch einen Begrenzer mit zwei Zeichen (Komma, gefolgt von einem Leerzeichen). Da überspringe Leer auf 0 steht, ignoriert VERBINDEN keine leeren Zeichenketten. Daher erscheinen im Rückgabetext zwei zusammenhängende Begrenzer, zwischen "John Doe" und "23 High Street". John Doe, , 23 High Street, Some Town, Some City
    =VERBINDEN(", "; 1; "John Doe"; ""; "23 High Street"; "Some Town"; "Some City") Dieses Beispiel ist ähnlich dem vorherigen Beispiel, außer dass überspringe Leer nicht mehr auf 0 steht und daher der extra Begrenzer zwischen "John Doe" und "23 High Street" nicht mehr auftaucht. John Doe, 23 High Street, Some Town, Some City
    =VERBINDEN({"+","-","="}; 0; {9,7,5,11}) Hier sind die Begrenzer in einer Aufzählung angegeben, wobei die zusammenzuhängenden Zeichenketten in einer numerischen Aufzählung angegeben sind. Die Begrenzer werden der Reihe nach verwendet und der exakte Wert von überspringe Leer ist unwichtig, da es keine leeren Zeichenketten gibt. 9+7-5=11
    =VERBINDEN(E1:F2, 0, A1:C3), wobei die Zellen E1, F1, E2 und F2 die Begrenzer " + ", " - ", " * " und " / " enthalten. Die Zellen A1 bis C3 enthalten die Adresse der Zellen, also Zelle A1 enthält "A1", Zelle B2 enthält "B2" usw. Dieses Beispiel zeigt, wie sich VERBINDEN verhält, wenn die Begrenzer und die zusammenzuhängenden Zeichenketten in einem Zellbereich angegeben sind. Die Zellen, die die Begrenzer enthaltenwerden zeilenweise von oben nach unten abgearbeitet. Und dieser Zyklus wird so oft wie nötig wiederholt. Die zusammenzuhängenden Zeichenketten werden auch zeilenweise von oben nach unten angearbeitet. In diesem Beispiel ist der exakte Wert von überspringe Leer ist unwichtig, da es im Bereich A1:C3 keine leeren Zellen gibt. A1 + B1 - C1 * A2 / B2 + C2 - A3 * B3 / C3

    Ähnliche LibreOffice Funktionen:

    TEXTKETTE

    VERKETTEN

    ODF Standard:

    Nichts.

    Betroffene (oder ähnliche) EXCEL-Funktionen:

    TEXTJOIN