Documentation/Fonctions Calc/JOINDRE.TEXTE

TDF LibreOffice Document Liberation Project Blogs communautaires Weblate Nextcloud Redmine Ask LibreOffice Donner

• Accueil
• Development
• Design
• QA
• Évènements
• Documentation
• Website
• Localisation
• Accessibility
• Marketing
• Diversity
• Aide

• Documentation
• Publications officielles
• Other Resources
• FAQ
• HowTo
• Macros
• Docs Development

Calc Functions Home | List of functions | Abbreviations

Nom de la fonction :

JOINDRE.TEXTE

Catégorie :

Text

Résumé :

Concatène plusieurs chaînes de texte en une seule chaîne, en insérant des délimiteurs entre chaque sous-chaîne.

La fonction JOINDRE.TEXTE est liée aux fonctions CONCAT et CONCATENER, mais offre la possibilité supplémentaire d'inclure des délimiteurs dans la chaîne concaténée.

Syntaxe :

JOINDRE.TEXTE(séparateur, ignorer_vide, chaîne1 [; chaîne2 [; … ;[ chaîne253]]])

Renvoie :

Renvoie une chaîne de texte formée en concaténant les arguments de chaîne bout à bout, avec des délimiteurs entre chaque sous-chaîne.

Arguments :

délimiteur est une chaîne de texte (entre guillemets), un nombre, une référence à une cellule, une référence à une plage de cellules ou un tableau en ligne de chaînes (entre accolades '{' et '}' ). délimiteur spécifie le texte à insérer entre chaque paire de sous-chaînes concaténées.

Skip Empty specifies whether empty cells / strings are included (0 or FAUX) or ignored (any other value). If set to 0 or FAUX to include empty cells / strings, then the returned string may include adjacent delimiters.

chaîne1 est une chaîne de texte (entre guillemets), un nombre, une référence à une cellule, une référence à une plage de cellules ou un tableau en ligne de chaînes (entre accolades '{' et '}'). chaîne1 spécifie la ou les premières chaînes qui doivent être concaténées.

String 2 through to String 253 are similar to String 1 but specify the subsequent strings that are to be concatenated.

• If Delimiter specifies multiple strings (e.g., a cell range or an inline array), the number of delimiters need not be of the same size as the number of strings to be concatenated. If there are more delimiters than strings to be concatenated, not all delimiters will be used. If there are less delimiters than strings to be concatenated, the delimiters will be re-used in a cyclic manner.
• If Skip Empty is non-numeric, then JOINDRE.TEXTE reports a #VALEUR ! error.
• When a cell range is specified, the cells are traversed row by row (from top to bottom). This applies both for the Delimiter argument and the String 1 through to String 253 arguments.
• The length of the string to be returned is limited to be less than 256 * (1024)² characters. If the arguments passed would cause this limit to be exceeded, JOINDRE.TEXTE reports a string overflow error (Err :513).

Détails complémentaires :

This function is not a requirement of ODF 1.2 but is compatible with the Microsoft Excel JOINDRE.TEXTE function.

Exemples :

Formule	Description	Renvoie
=JOINDRE.TEXTE(" "; 1; "Here"; "comes"; "the"; "sun")	Here the function concatenates the four string arguments, separating each pair with a space delimiter. In this example, the exact value of the Skip Empty argument is not significant because there are no empty strings to be concatenated.	Here comes the sun
=JOINDRE.TEXTE(B1; C1; D1; D2; D3; D4) where cell B1 contains the string "-", cell C1 contains the value 1, and cells D1 to D4 contain the strings "Here", "comes", "the", and "sun" respectively.	Here the function concatenates the four string arguments (passed by cell reference), separating each pair with a dash delimiter (also passed by cell reference). In this example, the exact value of the Skip Empty argument (again passed by cell reference) is not significant because there are no empty strings to be concatenated.	Here-comes-the-sun
=JOINDRE.TEXTE(", "; 0; "John Doe"; ""; "23 High Street"; "Some Town"; "Some City")	Here the function concatenates the string arguments, separating each pair with a two-character delimiter (comma followed by space). With the Skip Empty argument set to 0, JOINDRE.TEXTE does not ignore empty strings. Hence two adjacent delimiters appear in the returned string, between "John Doe" and "23 High Street".	John Doe, , 23 High Street, Some Town, Some City
=JOINDRE.TEXTE(", "; 1; "John Doe"; ""; "23 High Street"; "Some Town"; "Some City")	This example is similar to the previous example, except that the Skip Empty argument is no longer set to 0 and so the extra delimiter does not appear between "John Doe" and "23 High Street".	John Doe, 23 High Street, Some Town, Some City
=JOINDRE.TEXTE({"+","-","="}; 0; {9,7,5,11})	Here the delimiters are defined in an inline array of strings, while the strings to be concatenated are defined in an inline array of numbers. The delimiters are used in sequence and the exact value of the Skip Empty argument is not significant because there are no empty strings.	9+7-5=11
=JOINDRE.TEXTE(E1:F2, 0, A1:C3) where cells E1, F1, E2, and F2 contain the delimiter strings " + ", " - ", " * ", and " / " respectively. Cells A1 to C3 contain a string representing the cell’s address, so cell A1 contains "A1", cell B2 contains "B2", etc.	This example is helpful to demonstrate how JOINDRE.TEXTE behaves when the delimiters and strings to be concatenated are specified as cell ranges. The cells containing delimiter strings are traversed row by row, from top to bottom, and this cycle is repeated as often as needed. The strings to be concatenated are also traversed row by row, from top to bottom. In this example, the exact value of the Skip Empty argument is not significant because there are no empty cells in the range A1:C3.	A1 + B1 - C1 * A2 / B2 + C2 - A3 * B3 / C3

Fonctions LibreOffice associées :

CONCAT

CONCATENER

Standard ODF :

None.

Fonctions Excel équivalentes :

TEXTJOIN