Documentatie/Calc-functies/AGGREGAAT

This page is a translated version of the page Documentation/Calc Functions/AGGREGATE and the translation is 100% complete.

TDF LibreOffice Document Liberation Project Blogs gemeenschap Weblate Nextcloud Redmine Ask LibreOffice Doneren

Other languages:

Startpagina Calc-functies | Lijst met functies | Afkortingen

Functienaam:

AGGREGAAT

Categorie:

Wiskundig

Samenvatting:

AGGREGAAT is een krachtige maar complexe functie die een enkel getal berekent door een geselecteerde functie Aggregaat toe te passen op een gespecificeerde set gegevens. Er zijn negentien verschillende aggregaatfuncties beschikbaar.

In tegenstelling tot veel andere functies die vergelijkbare berekeningen uitvoeren, biedt AGGREGAAT opties om bepaalde ongewenste gegevenstypen uit de verwerking weg te laten. Er zijn opties beschikbaar om fouten, verborgen rijen en geneste SUBTOTAAL- en andere AGGREGAAT-functieresultaten te negeren.

Syntaxis:

AGGREGAAT(Functie; Opties; Verwijzing 1[; Verwijzing 2[; ... [; Verwijzing 253]]])

of

AGGREGAAT(Functie; Opties; Matrix; k)

De eerste syntaxis is bedoeld voor gebruik met Functie-waarden 1 tot 13, terwijl de tweede syntaxis bedoeld is voor gebruik met Functie-waarden 14 tot 19.

Retourneert:

Retourneert een numerieke waarde die het resultaat is van het toepassen van de geselecteerde aggregatiefunctie en negeeropties op de opgegeven set gegevens.

Argumenten:

Functie is een geheel getal in het bereik [1, 19], of een verwijzing naar een cel die dat getal bevat, waarmee de te gebruiken aggregatiefunctie wordt gespecificeerd. De volgende tabel toont de toewijzing van deze waarden aan aggregatiefuncties.

Functie-index	Functie toegepast
1	GEMIDDELDE
2	AANTAL
3	AANTALARG
4	MAX
5	MIN
6	PRODUCT
7	STDEV.S
8	STDEV.P
9	SOM
10	VAR.S
11	VAR.P
12	MEDIAAN
13	MODUS.ENKELV
14	GROOTSTE
15	KLEINSTE
16	PERCENTIEL.INC
17	KWARTIEL.INC
18	PERCENTIEL.EXC
19	KWARTIEL.EXC

Opties is een geheel getal in het bereik [0, 7], of een verwijzing naar een cel die dat getal bevat, waarmee wordt aangegeven welke negeeroptie moet worden gebruikt. De volgende tabel laat zien welke gegevenstypen voor elke waarde worden genegeerd.

Opties-index	Opties toegepast
0	Negeer alleen geneste SUBTOTAAL- en AGGREGAAT-functies
1	Negeer alleen verborgen rijen, geneste SUBTOTAAL- en AGGREGAAT-functies
2	Negeer alleen fouten, geneste SUBTOTAAL- en AGGREGAAT-functies
3	Negeer verborgen rijen, fouten, geneste SUBTOTAAL- en AGGREGAAT-functies
4	Negeer niets
5	Negeer alleen verborgen rijen
6	Negeer alleen fouten
7	Negeer alleen verborgen rijen en fouten

Verwijzing 1, Verwijzing 2, ..., Verwijzing 253 zijn de numerieke argumenten die moeten worden verwerkt wanneer Functie in het bereik [1, 13 ligt]. Deze zijn vergelijkbaar met die van de zelfstandige functies die worden gebruikt voor aggregatie, zie bijvoorbeeld GEMIDDELDE, AANTAL en MAX. Elk argument kan één van de volgende vormen aannemen:

Een getal of een uitdrukking die resulteert in een getal.
Een verwijzing naar een enkele cel die een getal bevat.
Een eenvoudige verwijzing naar een celbereik dat getallen bevat (bijvoorbeeld A1:B9).
De naam van een benoemd bereik, bestaande uit cellen met getallen.
De naam van een databasebereik, bestaande uit cellen met getallen.
Een ingebedde matrix van getallen (bijvoorbeeld {1, 2, 3, 4}).
De tekst van het koplabel boven een kolom met getallen, tussen enkele aanhalingstekens - alleen beschikbaar als de optie Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen ▸ Rij- en kolomkoppen automatisch zoeken is ingeschakeld (LibreOffice ▸ Voorkeuren ▸ LibreOffice Calc ▸ Berekenen ▸ Automatisch kolom- en rijlabels vinden op macOS).

Matrix bevat de numerieke argumenten die moeten worden verwerkt wanneer Functie in het bereik [14, 19] ligt. Dit argument is vergelijkbaar met het Gegevens-argument van de zelfstandige functies die worden gebruikt voor aggregatie, zie GROOTSTE, PERCENTIEL.EXC, PERCENTIEL.INC, KWARTIEL.INC, KWARTIEL.EXC en KLEINSTE. Het Matrix-argument kan één van de bovenstaande vormen aannemen voor Getal1, Getal2, ..., Getal253.

k is vereist wanneer Functie in het bereik [14, 19] ligt en specificeert het tweede argument dat vereist is voor de zelfstandige aggregatiefunctie. Deze zijn als volgt:

GROOTSTE vereist een argument Rang C (positief geheel getal).
KLEINSTE vereist een argument Rang C (positief geheel getal).
PERCENTIEL.INC vereist een argument Alfa (reëel getal in het bereik [0, 1]).
PERCENTIEL.EXC vereist een argument Alfa (reëel getal in het bereik (0, 1)).
KWARTIEL.INC vereist een argument Type (geheel getal in het bereik [0, 4]).
KWARTIEL.EXC vereist een argument Type (geheel getal in het bereik [1, 3]).

De volgende foutcondities kunnen optreden:

Als Functie of Opties niet numeriek is, dan retourneert AGGREGAAT als fout Ongeldig argument (Fout:502).
Als Functie of Opties geen geheel getal is, wordt de waarde afgekapt tot de minimumwaarde.
Als Functie kleiner is dan 1 of groter dan 19, dan retourneert AGGREGAAT als fout Ongeldig argument (Fout:502).
Als Opties kleiner is dan 0 of groter dan 7, dan retourneert AGGREGAAT als fout Ongeldig argument (Fout:502).
Afhankelijk van de geselecteerde aggregatiefunctie en de aangeleverde gegevens kunnen er andere fouten worden gegenereerd. Bijvoorbeeld een foutcode #DELING.DOOR.0! wordt gegenereerd als Functie is ingesteld op 7 (STDEV.S) en er slechts één gegevenswaarde wordt opgegeven. Een ander voorbeeld doet zich voor wanneer een foutcode #WAARDE! wordt gegenereerd als Functie is ingesteld op 13 (MODUS.ENKELV) en de geleverde gegevens geen dubbele gegevenspunten bevatten. Meer informatie over dergelijke foutcondities is te vinden op de wiki-pagina's voor de zelfstandige versies van de aggregaatfuncties.

Aanvullende details:

De AGGREGAAT-functie kan het beste worden gebruikt voor kolommen met gegevens, in plaats van rijen met gegevens, omdat het verbergen van kolommen geen effect heeft op de resultaten van AGGREGAAT.

Voorbeelden:

De volgende tabel toont voorbeeldgegevens die worden gebruikt in de volgende voorbeelden van de AGGREGAAT-functie.

	A	B	C
1	Kolom 1	Kolom 2	Kolom 3
2	34	11	12
3	10	56	35
4	#DELING.DOOR.0!	5	3
5	20	8	1
6	0	8	9
7	#WAARDE!	20	21
8	5	7	8
9	14	0	5

Formule	Beschrijving	Retourneert
=AGGREGAAT(1; 4; 1; 2; 3; 4; 5; 6)	Hier retourneert de functie de gemiddelde waarde (Functie ingesteld op 1) van de zes opgegeven getallen (1 tot 6, gespecificeerd in de derde tot achtste argumenten), waarbij niets wordt genegeerd (Opties ingesteld op 4).	3,5
=AGGREGAAT(4; 2; A2:A9)	Hier retourneert de functie de maximale waarde (Functie ingesteld op 4) over het celbereik A2:A9, verborgen rijen negerend, en geneste SUBTOTAAL en AGGREGAAT-functies (Opties ingesteld op 2). Dit voorbeeld demonstreert de kracht van AGGREGAAT in vergelijking met de equivalente zelfstandige functies. De formule `=MAX(A2:A9)` retourneert een #DELING.DOOR.0! fout, waarbij de fout in cel A4 wordt doorgegeven. Als deze fout wordt verholpen door een wijziging in cel A4, retourneert de formule `=MAX(A2:A9)` als fout #WAARDE!, het proberen te vinden van de fout in A7. Het gebruik van AGGREGAAT vermijdt een deel van de opschoning van gegevens die anders nodig zou zijn.	34
=AGGREGAAT(9; 5; A5:C5)	Hier retourneert de functie de som (Functie ingesteld op 9) over het celbereik A5:C5, waarbij alleen verborgen rijen worden genegeerd (Opties ingesteld op 5). Merk op dat het resultaat ongewijzigd blijft omdat sommige of alle kolommen A-C verborgen zijn.	29
=AGGREGAAT(9; 5; B2:B9)	Hier retourneert de functie de som (Functie ingesteld op 9) over het celbereik B2:B9, waarbij alleen verborgen rijen worden genegeerd (Opties ingesteld op 5). Houd er rekening mee dat het resultaat verandert als een van de rijen 2:9 wordt verborgen - als u bijvoorbeeld rij 7 verbergt, wordt het resultaat gewijzigd in 95.	115
=AGGREGAAT(2; 3; Blad.B2:Blad3.B9)	Er wordt aangenomen dat het document drie bladen bevat – met aangrenzende tabbladen Blad1, Blad2 en Blad3 in het gebied Bladtabbladen. Verder wordt aangenomen dat al deze drie tabbladen dezelfde gegevens bevatten in cellen A1 tot C9. Hier retourneert de functie de telling (Functie ingesteld op 2) over het driedimensionale celbereik Blad1.B2:Blad3.B9, verborgen rijen, fouten en geneste SUBTOTAAL- en AGGREGAAT-functies negeren (Opties ingesteld op 3).	24
=AGGREGAAT(E3; E5; 'KolomTwee') waarbij de cellen E3 en E5 respectievelijk de getallen 13,3 en 4,7 bevatten.	Aangenomen wordt dat de optie Extra ▸ Opties ▸ LibreOffice Calc ▸ Berekenen ▸ Rij- en kolomkoppen zoeken is ingeschakeld (LibreOffice ▸ Voorkeuren ▸ LibreOffice Calc ▸ Berekenen ▸ Rij- en kolomkoppen zoeken op macOS). Hier retourneert de functie de modus (Functie ingesteld op afgekapte waarde van 13) van de waarden in KolomTwee (cellen B2:B9), niets negeren (Opties ingesteld op afgekapte waarde van 4).	8
=AGGREGAAT(15; 4; C2:C9, 3)	Hier retourneert de functie de derde (k ingesteld op 3) kleinste (Functie ingesteld op 15) van de waarden in het celbereik C2:C9, niets negerend (Opties ingesteld op 4).	5